verbatimtex
%&latex
\def\ln{\par}
\documentclass{article}
\usepackage[latin1]{inputenc}
\usepackage[frenchb]{babel}
\usepackage{fourier}
\begin{document}
etex

path p[],seg[],arc[];
pair M[];

arc0 = fullcircle scaled 60;
arc1 = halfcircle xscaled 60 yscaled 20 rotated -23 ;
arc2 = halfcircle xscaled 60 yscaled -20 rotated -23;
arc3 = fullcircle xscaled 60 yscaled 20 rotated -23;
arc4 = fullcircle xscaled 450 yscaled 80;
arc5 = arc4 scaled .8;
arc6 = (point 5.4 of arc4)..(point 5.5 of arc4)..(point 5.6 of arc4);
seg0 = (-60,-75)--(60,75);
seg1 = .48(-40,-65)--.48(40,65);
M1 = .37(40,65);
M2 = arc4 intersectionpoint seg0;

beginfig(1);
    % la couronne
    fill arc4 withcolor .9white;
    fill arc5 withcolor white;
    
    % les rayons solaires
    for i:=0 upto 2:
    n := 5+(i/15);
    drawarrow (point n of arc4)--(point n of arc5)
        withpen pencircle scaled 2pt
        withcolor (1,1,0);
    endfor;
    
    % les marques de saisons
    draw (point 0 of arc4)--(point 0 of arc5)
        withpen pencircle scaled 1.5pt
        withcolor green;
    draw (point 4 of arc4)--(point 4 of arc5)
        withpen pencircle scaled 1.5pt
        withcolor green;
    draw M2--(M2 scaled .8)
        withpen pencircle scaled 1.5pt
	withcolor green;
    draw -M2--(-M2 scaled .8)
        withpen pencircle scaled 1.5pt
	 withcolor green;
    
    drawarrow arc6 scaled .9 withpen pencircle scaled 1.5pt;

    label.lft(btex \begin{minipage}{2.5cm}\small\it
                direction des\ln rayons solaires 
                \end{minipage}etex,
        point 5.1 of arc4);

    draw arc0;

    draw arc1 dashed evenly scaled 0.5;
    draw arc2;
    fill arc3 withcolor .9white;

    draw halfcircle xscaled 60 yscaled 16.5 dashed evenly scaled .5;
    draw halfcircle xscaled 60 yscaled -16.5;

    draw seg0 cutafter arc2 withpen pencircle scaled .15;
    draw seg0 cutbefore arc0 withpen pencircle scaled .15;
    draw (seg0 cutbefore arc2) cutafter arc0 dashed evenly scaled 0.5
        withpen pencircle scaled .15;

    draw (0,0) withpen pencircle scaled 4pt;
    draw (seg0 intersectionpoint arc2) withpen pencircle scaled 2pt;
    draw (seg0 intersectionpoint arc1) withpen pencircle scaled 2pt;
    draw seg1 cutbefore M1 withcolor blue;
    draw (seg1 cutafter M1) cutbefore arc0 dashed evenly scaled 0.5
        withpen pencircle scaled .15 withcolor blue;
    draw (seg1 cutafter M1) cutafter arc0 withcolor blue;

    label.lft(btex $PN$ etex scaled .7,M1);
    label.rt(btex $PS$ etex scaled .7,-M1);

    draw M1 withpen pencircle scaled 2pt withcolor blue;
    draw -M1 withpen pencircle scaled 2pt withcolor blue;

    label.lrt(btex $\gamma$ etex,point .1 of seg0);

    label.rt(btex Hiver etex, (-150,-60));
    label.lft(btex Printemps etex, (150,-60));
    label.lft(btex Été etex, (150,60));
    label.rt(btex Automne etex, (-150,60));

    label(btex \textbf{NB}: 
	    Les saisons indiquées sont celles de l'hémisphère nord. 
	  etex,(0,-90));
endfig;
end