u=1.2cm;
v=1.2mm;


beginfig(1);
draw (0,0)--(5u,0);
draw(u,-2u)--(u,2u);
draw(3u,-2u)--(3u,2u);
draw(u,-v)--(u+v,-v)--(u+v,0);
draw(u,1.2u)--(4u,1.2u)--(3u,0);
draw(u,1.1u)--(u+v,1.1u)--(u+v,1.2u);
drawarrow (u+v,-u)--(3u-v,-u);
drawarrow (3u-v,-u)--(u+v,-u);
pickup pencircle scaled 1pt;
drawarrow (3u,0)--(3.6u,0);
drawarrow (3u,0)--(3u,0.6u);
dotlabel.ulft(btex $K$ etex,(u,0));
dotlabel.ulft(btex $H$ etex,(u,1.2u));
dotlabel.llft(btex $F$ etex,(3u,0));
dotlabel.rt(btex $M$ etex,(4u,1.2u));
label.ulft(btex $\cal D$ etex,(u,-2u));
label.top(btex $\alpha$ etex,(2u,-u));
label.bot(btex $\vec i$ etex, (3.3u,0));
label.lft(btex $\vec j$ etex, (3u,0.3u));

endfig;

beginfig(2);
path parabole;
% axe focal
draw (0,0)--(5u,0);
% directrice
draw(u,-2u)--(u,2u);
% corde focale
draw(2.6u,-2u)--(2.6u,2u);
% angle droit en K
draw(u,-v)--(u+v,-v)--(u+v,0);
% tangente au sommet
draw(1.8u,-2u)--(1.8u,2u);
% la parabole
parabole = (3.466u,-2.30940u)..(3.1333u,-2.06559u)..(2.8u,-1.78885u)
			..(2.1333u,-1.03279u)..{dir 90}(1.8u,0){dir 90}
			..(2.1333u,1.03279u)..(2.4666u,1.46059u)..(2.8u,1.78885u)
			..(3.1333u,2.06559u)..(3.466u,2.30940u);
z1 = (2.6u , 0);
z2 = (z1--(2.6u, 2u)) intersectionpoint parabole;
z3 = (z1--(2.6u,-2u)) intersectionpoint parabole;
z4 = (u,0);
% vecteurs i et j
pickup pencircle scaled 1pt;
drawarrow (1.8u,0)--(2.4u,0);
drawarrow (1.8u,0)--(1.8u,0.6u);
draw parabole withcolor green;
% K
dotlabel.ulft(btex $K$ etex,(u,0));
% F
dotlabel.lrt(btex $F$ etex,(2.6u,0));
dotlabel.lrt(btex $M_1$ etex, z2);
dotlabel.urt(btex $M_2$ etex, z3);
label.rt(btex $p$ etex, 0.5[z1,z2]);
% S
dotlabel.llft(btex $S$ etex,(1.8u,0));
% D
label.ulft(btex $\cal D$ etex,(u,-2u));
% delta	
label.top(btex $\Delta$ etex,(4.8u,0));
% i,j
label.bot(btex $\vec i$ etex, (2.1u,0));
label.lft(btex $\vec j$ etex, (1.8u,0.3u));
clip currentpicture to (0,-2u)--(0,2u)--(5u,2u)--(5u,-2u)--cycle;
endfig;


beginfig(3)
% excentricité : 0.65
path ellipse;
numeric a,b,c,e;
e := 0.65;
a := 1.3u;
b := a*sqrt(1-e**2);
c := a*e;
ellipse = fullcircle xscaled 2a yscaled 2b;
% axe focal
draw (-2.5u,0)--(2.5u,0);
% axe non focal
draw (0,-2u)--(0,2u);
% points
z0 = (0,0);
z1 = (-a,0);
z2 = (-a/e,0);
z3 = (-c,0);
z0 = 0.5[z1,z4];
z0 = 0.5[z2,z5];
z0 = 0.5[z3,z6];
draw z3--(0,b);
% directrices
draw(-2u,-2u)--(-2u,2u);
draw(2u,-2u)--(2u,2u);
pickup pencircle scaled 1pt;
draw ellipse withcolor green;
drawarrow (0,0)--(0.6u,0);
drawarrow (0,0)--(0,0.6u);
% i,j
label.bot(btex $\vec i$ etex, (0.3u,0));
label.lft(btex $\vec j$ etex, (-0.01u,0.3u));
% labels
dotlabel.llft(btex $K$ etex,z2);
dotlabel.lrt(btex $K'$ etex,z5);
dotlabel.llft(btex $A$ etex,z1);
dotlabel.lrt(btex $A'$ etex,z4);
dotlabel.bot(btex $F$ etex,z3);
dotlabel.bot(btex $F'$ etex,z6);
dotlabel.llft(btex $O$ etex,z0);
dotlabel.urt(btex $B$ etex,(0,b));
dotlabel.lrt(btex $B'$ etex,(0,-b));
label.lft(btex $\delta$ etex,(0,-1.8u));
label.lft(btex $\cal D$ etex,(-2u,-1.8u));
label.rt(btex ${\cal D}'$ etex,(2u,-1.8u));
label.lft(btex $a$ etex,0.5[z3,(0,b)]);
label.rt(btex $b$ etex, (0,0.5b));
% ------------------------
clip currentpicture to (-2.5u,-2u)--(-2.5u,2u)--(2.5u,2u)--(2.5u,-2u)--cycle;
endfig;

beginfig(4);
path hyperbole;
numeric a,b,c,e;
a	:=	1.3u;
c	:=	2u;
e	:=	c/a;
b	:=	a*sqrt(e**2-1);
% branche droite de l'hyperbole d'équation x^2-y^2=1;	
hyperbole = for i=-10 upto 9:
				(1 / cosd(i*8),sind(i*8)/cosd(i*8))..
			endfor
			(1 / cosd(80),sind(80)/cosd(80));
% axes focaux
draw (-2.5u,0)--(2.5u,0);
draw (0,-2u)--(0,2u);
% directrices
draw(a/e,-2u)--(a/e,2u);
draw(-a/e,-2u)--(-a/e,2u);
% asymptotes
draw (-a*2*u/b,-2u)--(a*2*u/b,2u);
draw (a*2*u/b,-2u)--(-a*2*u/b,2u);
% tracé de l'hyperbole
pickup pencircle scaled 1pt;
draw hyperbole xscaled a yscaled b withcolor green;
draw hyperbole xscaled -a yscaled b withcolor green;
drawarrow (0,0)--(0.6u,0);
drawarrow (0,0)--(0,0.6u);
% les labels
dotlabel.llft(btex $K$ etex,(-a/e,0));
dotlabel.llft(btex $K'$ etex,(a/e,0));
dotlabel.llft(btex $A$ etex,(-a,e));
dotlabel.llft(btex $A'$ etex,(a,0));
dotlabel.llft(btex $F$ etex,(-c,0));
dotlabel.llft(btex $F'$ etex,(c,0));
dotlabel.llft(btex $O$ etex,(0,0));
label.lft(btex $\delta$ etex,(0,-1.8u));
label.lft(btex $\cal D$ etex,(-a/e,-1.8u));
label.rt(btex ${\cal D}'$ etex,(a/e,-1.8u));
label.top(btex $\vec i$ etex, (0.6u,0));
label.ulft(btex $\vec j$ etex, (-0.01u,0.6u));
% ---
clip currentpicture to (-2.5u,-2u)--(-2.5u,2u)--(2.5u,2u)--(2.5u,-2u)--cycle;
endfig;

beginfig(5);
path axex,axey,bissec;
w = 0.6cm;
z0 	=	(-5*w,-3*w);
axex = (-15w,0)--(15w,0);
axey = (0,-15w)--(0,15w);
bissec = (-15w,-15w)--(15w,15w);
draw axex shifted z0;
draw axey shifted z0;
draw bissec shifted z0;
draw bissec;
draw (-15w,15w)--(15w,-15w);
draw axex;
draw axey;
drawarrow (0,0)--(0,10w);
drawarrow (x0,0)--(x0,10w);
drawarrow (0,0)--(8w,0);
drawarrow (0,y0)--(8w,y0);
pickup pencircle scaled 1pt;
draw hyperbole scaled (sqrt(38)*w) rotated 45 shifted z0 withcolor red;
draw hyperbole scaled -(sqrt(38)*w) rotated 45 shifted z0 withcolor red;
drawarrow (0,0)--(w,0);
drawarrow (0,0)--(0,w);
drawarrow (0,0)--(-10w,10w);
label.llft (btex $Y$ etex, (-10w,10w));
drawarrow (0,0)--(8w,8w);
label.ulft(btex $X$ etex, (8w,8w));
drawarrow ((0,0)--(w,0)) shifted z0;
drawarrow ((0,0)--(0,w)) shifted z0;
dotlabel.lrt(btex $O$ etex, (0,0));
dotlabel.ulft(btex $\Omega$ etex, z0);
z1 = (hyperbole scaled (sqrt(38)*w) rotated 45 shifted z0) 
	intersectionpoint (bissec shifted z0);
z2 = (hyperbole scaled -(sqrt(38)*w) rotated 45 shifted z0) 
	intersectionpoint (bissec shifted z0);
dotlabel.top(btex $A$ etex, z1);
dotlabel.bot(btex $A'$ etex, z2);
label.bot(btex $\vec i$ etex, (w,0));
label.urt(btex $\vec j$ etex, (0,0.8w));
label.lft(btex $y$ etex, (0,9.8w));
label.lft(btex $y'$ etex, (x0,9.8w));
label.bot(btex $x$ etex, (7.8w,0));
label.bot(btex $x'$ etex, (7.8w,y0));
label.ulft(btex $-5$ etex, (-5w,0));
label.lrt(btex $-3$ etex, (0,-3w));
clip currentpicture to (-12w,-10w)--(-12w,10w)--(8w,10w)--(8w,-10w)--cycle;
endfig;
end