\Titre{Une conique et ses tangentes}

.m >MPPREFIXE:"coniques04"$
.m >load("coniques04.lisp")$

\begin{gbar}
Reconnaître et caractériser l'ensemble défini dans le plan euclidien
muni d'un repère $(O,\vec\imath,\vec\jmath)$ par l'équation:
$$13x^2-32xy+37y^2-5=0$$
Donner l'équation de la tangente au point $M_0(x_0,y_0)$. Chercher les points
pour lesquels la tangente est parallèle à l'axe $(O,\vec\imath)$.
\end{gbar}

Commençons par reconnaître la conique et effectuons en le tracé.
.m load("reduction.mc")$
.m (eq:13*x^2-32*x*y+37*y^2-5,Reduction(eq));
.m Elements();
.m RotationTranslation();
.m Representation(-2,-2,2,2,2);
Partons à la recherche des équations des tangentes.
.m (f(x,y):=13*x^2-32*x*y+37*y^2,'f(x,y)=f(x,y));
.m (g(x,y):=a*x+b*y,'g(x,y)=g(x,y));

En résolvant le système
$\begin{cases}f(x,y)=f(x_0,y_0)\\g(x,y)=g(x_0,y_0)\end{cases}$
nous déterminerons les points d'intersection d'une droite et de l'ellipse
passant toutes les deux par le point $M_0(x_0,y_0)$.

.m sol:solve([f(x,y)-f(x0,y0),g(x,y)-g(x0,y0)],[x,y]);

La droite sera tangente à l'ellipse lorsque les deux points ci-dessus
seront confondus.

.m ab:solve([rhs(part(sol,2,1))-x0,rhs(part(sol,2,2))-y0],[a,b]);

La deuxième solution proposée, $(a=0,b=0)$, est à écarter --- $g$ ne caractériserait
pas une droite ---, il ne reste que la première dans laquelle figure une constante
arbitraire $R_1$ que nous fixerons égale au dénominateur de l'expression de $b$.

.m s:block([b],b:rhs(ab[1][2]),ab:subst(denom(b),%R1,ab[1]),radcan(ab));

Il ne reste qu'à écrire l'équation de la tangente.
.m e:block(a:rhs(s[1]),b:rhs(s[2]),rat(g(x,y)-g(x0,y0),y0,x0,y,x)=0);

On reconnaît le terme constant, il est égal à $f(x_0,y_0)$ lui même égal à $5$.
Voici donc le résultat recherché:
.m a*x+b*y+5=0;

Nous aurions pu obtenir le même résultat avec la \emph{règle du dédoublement}\footnote{Qui
se justifie bien avec le gradient.} en substituant $xx_0$ à $x^2$, $\frac12(xy_0+x_0y)$ à
$xy$ et $yy_0$ à $y^2$ dans l'équation de l'ellipse.

.m (e:ev(eq,x^2=x*x0,y^2=y*y0),e:ratsubst(1/2*(x0*y+x*y0),x*y,e),e);

Les substitutions sont faites, ordonnons.

.m rat(e,y0,x0,y,x)=0;

Nous retrouvons bien la même équation, au signe près.

Maintenant recherchons les points de l'ellipse où la tangente est parallèle à l'axe des
abscisses c'est à dire lorsque $a=0$.
.m s:solve(a=0,x0);
.m y:(x0:rhs(s[1]), solve(f(x0,y0)-5));
Nous avons les ordonnées des deux points attendus, voici les points.
.m [subst(y[1],[x0,y0]),subst(y[2],[x0,y0])];
\vfill
\begin{flushright}\small\itshape
JMS -- 13 novembre 2005
\end{flushright}