%@AUTEUR:Guillaume Connan
prologues:=2;

input courbes;
input geo;

color vert_e, turquoise, orange, vert_fonce, rose, vert_mer, bleu_ciel, or, rouge_v,bleu_m,bleu,bleu_f;
vert_e:=(0,0.790002,0.340007);
turquoise:=(0.250999,0.878399,0.815699);
orange:=(0.589999,0.269997,0.080004);
vert_fonce:=(0,1.4*0.392193,0);
rose:=(1.0, 0.752907, 0.796106);
bleu_ciel:=(1.2*0.529405,1.2*0.807794,1);%.2*0.921598);
or:=(1,0.843104,0);
rouge_v:=(0.829997,0.099994,0.119999);
bleu_m:=(0.7*0.529405,0.7*0.807794,0.7);%*0.921598);
bleu_f:=(0.211762,0.3231176,0.3686392);
bleu:=(0.529405,0.807794,1);

%fonction décroissante et pentes

% Déclarations des constantes %
numeric xmin, xmax, ymin, ymax, W;

ux:=1cm;  uy:=0.8cm;
xmin := -.5 ; xmax := 5.5;
ymin := -.5 ; ymax := 4 ;

% Définitions des axes et labels associés
vardef axes =
  drawarrow (ux*xmin,0) -- (ux*xmax,0) ; % axe des x
  drawarrow (0,uy*ymin) -- (0,uy*ymax); % axe des y
  label.lrt(btex $x$ etex,(xmax*ux,0)); % label de l'axe des x
  label.urt(btex $y$ etex,(0,ymax*uy)); % label de l'axe des y
enddef;
  
beginfig(1);

  axes;

% Shifts
  
  pair h,g;
  h:=(0,.1*uy);
  g:=(-.1*ux,0);
  
% Courbe
  
  path N;
  
  N:=(.5*ux,3.5*uy){dir-70}..(5*ux,.5*uy){dir-10};
  
  draw N withpen pencircle scaled 1.3bp withcolor bleu_f;
  label.urt(btex $y=f(x)$ etex,(5*ux,.5*uy)) withcolor bleu_f;
  
  pair A,B;
  A:=point 0.2 of N ;
  B:=point 0.7 of N ;
  draw A withpen pencircle scaled 3bp withcolor 0.6white;
  draw B withpen pencircle scaled 3bp withcolor 0.6white;
  
  pair M,P;
  M:=direction 0.2 of N;
  P:=direction 0.7 of N;
  
  drawarrow (A--(A shifted .6M)) withpen pencircle scaled 1.3bp withcolor 0.6white;
  drawarrow (A--(A shifted -.6M))withpen pencircle scaled 1.3bp withcolor 0.6white;
  drawarrow (B--(B shifted .6P))withpen pencircle scaled 1.3bp withcolor 0.6white;
  drawarrow (B--(B shifted -.6P))withpen pencircle scaled 1.3bp withcolor 0.6white;
endfig;
end