%@AUTEUR: David Nivaud

verbatimtex
%&latex
\documentclass{article}
\begin{document}
etex

marksize=4pt;

def draw_mark(expr p, a)=
   begingroup
   save t, dm; pair dm;
   t = arctime a of p;
   dm = marksize*unitvector direction t of p
   rotated 90 ;
   draw (-0.5dm..0.5dm) shifted point t of p;
   endgroup
enddef;

def draw_marked (expr p, n) =
   begingroup
   save amid;
   amid = 0.5*arclength p;
   for i=-(n-1)/2 upto (n-1)/2:
      draw_mark (p,amid+0.6marksize*i);
   endfor
   draw p;
   endgroup
enddef;

angle_radius=8pt;

def mark_angle (expr a, b, c, n) =
   begingroup
   save s, p; path p;
   p = unitvector(a-b){(a-b)rotated 90}..unitvector(c-b);
   s = 0.9marksize/length(point 1 of p - point 0 of p);
   if s<angle_radius: s:=angle_radius; fi
   draw_marked(p scaled s shifted b,n);
   endgroup
enddef;

def mark_rt_angle(expr a, b, c) =
   draw((1,0)--(1,1)--(0,1))
   zscaled (angle_radius*unitvector (a-b)) shifted b
enddef;

beginfig(1);
u:=0.5 cm;
z0=(0,1.5u); z1=(5u,4u); draw z0--z1 ;%definition de l'axe
z3 =(2u,5u); %définition de M%
z4=(4u,1u); %definition de M'%
draw z3--z4; %segment [MM']
z5=0.5[z3,z4]; %milieu de [MM']

mark_rt_angle(z3, z5, z0); %angle droit ça tourne dans le sens
                           %trigonometrique
dotlabel.top(btex $M$ etex, z3); %ecriture de M au-dessus de z4
dotlabel.bot(btex $M'$ etex, z4);%ecriture de M' en-dessous de z3
label.bot(btex $(\Delta)$ etex, z0);%ecriture de (Delta) en-dessous de z0
draw_marked(z4--z5,2); %ecriture des deux traits indiquant l'égalité des
%longueurs sur [z4z5]
draw_marked(z3--z5,2); %ecriture des deux traits indiquant l'égalité des
%longueurs sur [z3z5]
endfig;


beginfig(2);
u:=1 cm;
z0=(2u,2u); z1=(5u,4u);
drawarrow z0..z1 ;
z2 =0.5[z0,z1];
dotlabel.bot(btex $M$ etex, z0);
label.top(btex $M'$ etex, z1);
label.top(btex $\vec{u}$ etex, z2);
endfig;

beginfig(3);
u:=0.5 cm;
z0=(0,0); z1=(2u,2u);
drawarrow z0..z1 ;
z2 =2[z0,z1];
drawarrow z0..z2;
dotlabel.bot(btex $O$ etex, z0);
label.ulft(btex $M$ etex, z1);
label.top(btex $M'$ etex, z2);
z3=(2.5u,0u);
label.top(btex $k=2$ etex, z3);

endfig;

beginfig(4);
u:=1 cm;
z0=(2u,2u); z1=(4u,3u);
drawarrow z0..z1 ;
z2 =z0+1/3(z0-z1);
drawarrow z0..z2;
dotlabel.bot(btex $O$ etex, z0);
label.top(btex $M$ etex, z1);
label.ulft(btex $M'$ etex, z2);
z3=(3.2u,1.6u);
label.top(btex $k=-\frac{1}{3}$ etex, z3);

endfig;

beginfig(5);
u:=1 cm;
z0=(1u,1u); z1=(3u,1u);
drawarrow z0..z1 ;
z2-z0 =(z1-z0) rotated 60;
drawarrow z0..z2;
draw z1{up}..z2 dashed evenly;
z3=0.3[z0,z1];
z4=0.3[z0,z2];
drawarrow z3{up}..z4;
%mark_angle(z1,z0,z2,0);
draw_marked(z0--z1,2);
draw_marked(z0--z2,2);
dotlabel.bot(btex $O$ etex, z0);
label.bot(btex $M$ etex, z1);
label.top(btex $M'$ etex, z2);
z5=(1.8u,1.3u);
label.top(btex $\alpha$ etex, z5);
z6=(2u,0.5u);
label.bot(btex $\alpha={\pi\over 3}$ etex, z6);
endfig;

beginfig(6);
u:=1 cm;
z0=(2u,2u); z1=(5u,4u);
drawarrow z0..z1 ;
z2 =0.5[z0,z1];
label.ulft(btex $M$ etex, z0);
label.ulft(btex $M'$ etex, z1);
label.top(btex $\vec{u}$ etex, z2);

z3=(2u,0u); z4=(5u,2u);
drawarrow z3..z4 ;
z5 =0.5[z3,z4];
label.bot(btex $N$ etex, z3);
label.lrt(btex $N'$ etex, z4);
label.top(btex $\vec{u}$ etex, z5);

drawarrow z0..z3;
drawarrow z1..z4;
endfig;

beginfig(7);
u:=0.5 cm;
z0=(0,0); z1=(2u,2u);
draw z0--z1 ;
z2 =2[z0,z1];
draw z0--z2;
dotlabel.bot(btex $O$ etex, z0);
dotlabel.ulft(btex $M$ etex, z1);
dotlabel.top(btex $M'$ etex, z2);

z3=(2u,0u);
draw z0--z3 ;
z4 =2[z0,z3];
draw z0--z4;
label.bot(btex $N$ etex, z3);
label.bot(btex $N'$ etex, z4);

drawarrow z1..z3;
drawarrow z2..z4;

z5=(1u,4u);
label.bot(btex $k >1$ etex, z5);
endfig;

beginfig(8);
u:=1 cm;
z0=(0,0); z1=(2u,2u);
draw z0--z1 ;
z2 =2[z0,z1];
draw z0--z2;
dotlabel.bot(btex $O$ etex, z0);
dotlabel.ulft(btex $M'$ etex, z1);
dotlabel.top(btex $M$ etex, z2);

z3=(2u,0u);
draw z0--z3 ;
z4 =2[z0,z3];
draw z0--z4;
label.bot(btex $N'$ etex, z3);
label.bot(btex $N$ etex, z4);

drawarrow z1..z3;
drawarrow z2..z4;

z5=(1u,3u);
label.bot(btex $0<k<1$ etex, z5);
endfig;

beginfig(9);
u:=1 cm;
z0=(2u,2u); z1=(4u,3u);
draw z0--z1 ;
z2 =z0+1/3(z0-z1);
draw z0--z2;
dotlabel.bot(btex $O$ etex, z0);
dotlabel.top(btex $M$ etex, z1);
dotlabel.bot(btex $M'$ etex, z2);

z3=(3u,1u);
draw z0--z3 ;
z4 =z0+1/3(z0-z3);
draw z0--z4;
label.bot(btex $N$ etex, z3);
label.top(btex $N'$ etex, z4);

drawarrow z1..z3;
drawarrow z2..z4;

z5=(2.5u,3.5u);
label.bot(btex $-1<k<0$ etex,z5);
endfig;

beginfig(10);
u:=1 cm;
z0=(2u,2u); z1=(4u,3u);
draw z0--z1 ;
z2 =z0+1/3(z0-z1);
draw z0--z2;
dotlabel.bot(btex $O$ etex, z0);
dotlabel.top(btex $M'$ etex, z1);
dotlabel.bot(btex $M$ etex, z2);

z3=(3u,1u);
draw z0--z3 ;
z4 =z0+1/3(z0-z3);
draw z0--z4;
label.bot(btex $N'$ etex, z3);
label.top(btex $N$ etex, z4);

drawarrow z1..z3;
drawarrow z2..z4;

z5=(2u,4u);
label.bot(btex $k<-1$ etex,z5);
endfig;


beginfig(11);
u:=0.8 cm;
z0=(1u,1u); z1=(3u,1u);
draw z0..z1 dashed evenly;
z2-z0 =(z1-z0) rotated 60;
draw z0..z2 dashed evenly;
draw z1{up}..z2 dashed withdots;
z3=0.3[z0,z1];
z4=0.3[z0,z2];
drawarrow z3{up}..z4;
dotlabel.bot(btex $O$ etex, z0);
label.bot(btex $M$ etex, z1);
label.urt(btex $M'$ etex, z2);
z5=(1.8u,1.1u);
label.top(btex $\alpha$ etex, z5);

z6=(4u,3u);
draw z0..z6  dashed evenly;
z7-z0 =(z6-z0) rotated 60;
draw z0..z7 dashed evenly;
draw z6..{left}z7 dashed withdots;
z8=0.3[z0,z6];
z9=0.3[z0,z7];
drawarrow z8{up}..z9 ;
label.lrt(btex $N$ etex, z6);
label.top(btex $N'$ etex, z7);

drawarrow z1..z6;
drawarrow z2..z7;
z51=(1.5u,2.3u);
label.top(btex $\alpha$ etex, z51);

z10=(6u,1u);
z11=(7u,3u);
z12-z10=(z11-z10) rotated 60;
drawarrow z10..z11;
drawarrow z10..z12;
draw_marked (z10--z11,2);
draw_marked (z10--z12,2);
z13=0.3[z10,z11];
z14=0.3[z10,z12];
drawarrow z13{dir 110}..z14;
label.lrt(btex $\overrightarrow{MN}$ etex, 0.5[z10,z11]);
label.llft(btex $\overrightarrow{M'N'}$ etex, 0.5[z10,z12]);
z15=(6u,2u);
label.top(btex $\alpha$ etex, z15);

endfig;

beginfig(12);
u:=0.5 cm;
z0=(0,1.5u); z1=(5u,4u); draw z0--z1 ;
z3 =(2u,5u); %définition de M%
z4=(4u,1u); %definition de M'%
draw z3--z4; %segment [MM']
z5=0.5[z3,z4]; %milieu de [MM']

mark_rt_angle(z3, z5, z0); %angle droit ça tourne dans le sens
                           %trigonometrique
dotlabel.top(btex $M$ etex, z3); %ecriture de M au-dessus de z4
dotlabel.bot(btex $M'$ etex, z4);%ecriture de M' en-dessous de z3
label.bot(btex $(\Delta)$ etex, z0);%ecriture de (Delta) en-dessous de z0
draw_marked(z4--z5,2); %ecriture des deux traits indiquant l'égalité des
%longueurs sur [z4z5]
draw_marked(z3--z5,2); %ecriture des deux traits indiquant l'égalité des
%longueurs sur [z3z5]
z6=0.1[z0,z1];
dotlabel.ulft(btex $I$ etex, z6);
draw z6--z3;
draw z6--z4;
draw_marked(z6--z3,1);
draw_marked(z6--z4,1);
endfig;

end