path ax,ay,ca,cb;
pair O,X,Y;
u   =  1cm;
O   =  (0,0);
X   =  (4.9u,0);
Y   =  (0,4.9u);
ax  =  (-3u,0)--(5u,0);
ay  =  (0,-3u)--(0,5u);
ca  =  (4*cosd(30)*cosd(15)*u,4*cosd(30)*sind(15)*u)
       for i = 0 upto 10:
         ..(4*cosd(30+10*i)*cosd(15+5*i)*u,4*cosd(30+10*i)*sind(15+5*i)*u)
       endfor;
cb  =  (2.5*(cosd(30)+1)*cosd(15)*u,2.5*(cosd(30)+1)*sind(15)*u)
       for i = 1 upto 10:
          ..(2.5*(cosd(30+10*i)+1)*cosd(15+5*i)*u,
				    2.5*(cosd(30+10*i)+1)*sind(15+5*i)*u)
       endfor;
%==============================================================================

beginfig(1);
pair Ma;
path cx,tm;
cx = cb rotated -90 shifted (0,4u) scaled 0.9;
drawarrow ax;
drawarrow ay;
z1      =       point (directiontime (-1,2) of cx) of cx;
tm      =       (x1+2u,y1-4u)--(x1-2u,y1+4*u);
z2      =       (tm intersectionpoint ax);
draw O--2z1;
draw (x1-2y1,y1+2x1)--(x1+2y1,y1-2x1);
draw tm;
drawarrow ((fullcircle scaled 1.5u shifted z1)
        cutafter ((x1,y1)--(x1-2u,y1+4*u))) cutbefore (O--2z1) ;
drawarrow ((fullcircle scaled 1.5u shifted z2)
        cutafter (z2--z1)) cutbefore ax;
drawarrow ((fullcircle scaled 1.5u shifted O)
        cutafter (O--z1)) cutbefore ax;
pickup pencircle scaled 1pt;
draw cx;
drawarrow z1--(1.4z1);
drawarrow z1--(x1-0.4y1,y1+0.4x1);
% ------------------------
clip currentpicture to (-2u,-2u)--(-2u,5u)--(5u,5u)--(5u,-2u)--cycle;
label.llft(btex $x$ etex,X);
label.llft(btex $y$ etex,Y);
dotlabel.rt(btex $ $ etex,z1);
label.rt(btex $M$ etex,z1+(1mm,0));
dotlabel.llft(btex $O$ etex,O);
label.lrt(btex $\vec u_{\theta}$ etex,1.4z1);
label.bot(btex $\vec v_{\theta}$ etex,(x1-0.4y1,y1+0.4x1));
label.rt(btex $\theta$ etex, (.6u,.5u));
label.rt(btex $\theta+V$ etex, z2+(.6u,.5u));
label.top(btex $V$ etex, z1+(.2u,.75u));
endfig;
%==============================================================================

beginfig(2);
path cc,cd;
cc      =       (-2u,0)--(2u,0);
cd      =       (0,0)..(0.5u,0.45u)..(u,.8u)..(2u,1.2u);
drawarrow cc;
drawarrow cc rotated 90;
drawarrow cc shifted (5u,0);
drawarrow cc rotated 90 shifted (5u,0);
draw (-2u,-2u)--(2u,2u);
draw ((-2u,-2u)--(2u,2u)) shifted (5u,0);
drawarrow ((fullcircle scaled 1.5u) 
    cutafter (O--(u,u))) 
    cutbefore (O--(2u,0));
drawarrow (((fullcircle scaled 1.5u) 
    cutafter (O--(u,u))) 
    cutbefore (O--(2u,0))) 
    shifted (5u,0);
pickup pencircle scaled 1pt;
draw cd;
draw cd zscaled (0,1) yscaled -1;
draw cd shifted (5u,0);
draw cd zscaled (0,1) xscaled -1 shifted (5u,0);
label.lft(btex $y$ etex,(0,2u));
label.bot(btex $x$ etex,(2u,0));
label.lft(btex $y$ etex,(5u,2u));
label.bot(btex $x$ etex,(7u,0));
dotlabel.ulft(btex $O$ etex,(0,0));
dotlabel.ulft(btex $O$ etex,(5u,0));
label.rt(btex $\theta_0$ etex,(0.8u,0.3u));
label.rt(btex $\theta_0$ etex,(5.8u,0.3u));
endfig;
%==============================================================================

beginfig(3);
path ce;
ce = (6u,0.1666u)..(5u,0.2u)..(4u,0.25u)..(3u,0.333u)..
     (2u,0.5u)..(u,u)..(0.5u,2u)..(-0.3u,3.33u);
drawarrow ax;
drawarrow ay;
drawarrow (-3u,-2.25u)--(5u,3.75u);
drawarrow (2.25u,-3u)--(-3u,4u);
draw ((-3u,-2.25u)--(5u,3.75u)) shifted (0,1.5u);
draw ((2u,0.5u)--(-0.85u,0.5u)) 
    zscaled (0.8,0.6) 
    shifted (0,1.5u) 
    dashed evenly;
z3 = (2u,0.5u) zscaled (0.8,0.6) shifted (0,1.5u);
draw O--z3;
drawarrow ((fullcircle scaled 1.5u) 
    cutafter (O--z3)) 
    cutbefore ax;
drawarrow ((fullcircle scaled 2.1u) 
    cutafter (O--(4u,3u))) 
    cutbefore ax;
drawarrow ((fullcircle scaled 2.7u) 
    cutafter (O--z3)) 
    cutbefore (O--(4u,3u));
pickup pencircle scaled 1pt;
draw ce zscaled (0.8,0.6) shifted (0,1.5u);
% ------------------------
clip currentpicture to (-3u,-3u)--(-3u,5u)--(5u,5u)--(5u,-3u)--cycle;
dotlabel.top(btex $M$ etex,z3);
label.llft(btex $x$ etex,X);
label.llft(btex $y$ etex,Y);
z4 = (((-3u,-2.25u)--(5u,3.75u)) shifted (0,1.5u))
        intersectionpoint ((2.25u,-3u)--(-3u,4u));
label.bot(btex $Y_0$ etex, z4-(0,0.1u));
label.lft(btex $f(\theta)\sin(\theta-\theta_0)$ etex, (x4-0.4u,y4+0.4u));
dotlabel.lft(btex $ $ etex,O);
label.llft(btex $O$ etex,(0,-2mm));
label.bot(btex $X$ etex,(5u,3.75u-1mm)) ;
label.lft(btex $Y$ etex,(-3u-1mm,4u));
label.rt(btex $\theta$ etex, (x3-0.83u,0.33y3-0.22u));
label.rt(btex $\theta_0$ etex, (x3-0.3u,0.33y3-0.6u));
label.rt(btex $\theta-\theta_0$ etex, (x3-0.65u,0.33y3+0.4u));
endfig;

end