input geometrie2d;
gTRD := 1.6;

beginfig(1);

 % Le quadrilatère complet
 A = Point(0,0); 
 B = Point(8,0); 
 C = Point(7,4);
 Q = QComplet(A,B,C,0.4,1.3);
 D = PointDe(Q,4);
 E = PointDe(Q,5);
 F = PointDe(Q,6);
 
 % Les cercles circonscrit
 c1 = CercleCirconscrit(Triangle(A,B,C));
 c2 = CercleCirconscrit(Triangle(A,D,F));
 c3 = CercleCirconscrit(Triangle(D,B,E));
 c4 = CercleCirconscrit(Triangle(E,F,C));
 
 % Le point de Miquel
 M = Point_((Lieu c1) intersectionpoint (Lieu c2));

 % Les projetés
 I = Projection(M,Droite(A,B));
 J = Projection(M,Droite(B,C));
 K = Projection(M,Droite(C,A));
 L = Projection(M,Droite(D,E));

 % Le dessin
 trace Droite(B,J);
 
 trace Q
    withpen pencircle scaled 1.5 withcolor (0.5,0.6,0.9);

 for i=1 upto 4: trace c[i] withcolor 0.3 white; endfor;
 
 trace Droite(I,J) withcolor 0.7red;
 
 trace Segment(M,I) withpen pencircle scaled 1pt dashed withdots;
 trace Segment(M,J) withpen pencircle scaled 1pt dashed withdots;
 trace Segment(M,K) withpen pencircle scaled 1pt dashed withdots;
 trace Segment(M,L) withpen pencircle scaled 1pt dashed withdots;
 
 marque.top  "M";
 marque.llft "A";
 marque.lrt  "B";
 marque.lrt  "C";
 marque.bot  "D";
 marque.urt  "E";
 marque.lrt  "F";

 pointe I;
 pointe J;
 pointe K;
 pointe L;        
endfig;
end