input geometrie2d;

beginfig(1);

    a = 35;
    b = 40;
    a + b + c = 120;
    
    vardef sommet(expr u,v,w) =
	save p,q;
	p = Rotation(v,u,-w);
	q = Rotation(u,v,w);
	Intersection(Droite(u,p),Droite(v,q))
    enddef;
        
    P = Point(0,0);
    Q = Point(2,0);
    R = Rotation(Q,P,60);
    
    T = Triangle(P,Q,R);
    
    P'= sommet(Q,R,a);
    Q'= sommet(R,P,b);
    R'= sommet(P,Q,c);

    A = Intersection(Droite(Q',R),Droite(R',Q));
    B = Intersection(Droite(R',P),Droite(P',R));
    C = Intersection(Droite(P',Q),Droite(Q',P));
        
    trace Triangle(Q,R,P');
    trace Triangle(R,P,Q');
    trace Triangle(P,Q,R');

    trace Segment(A,Q');
    trace Segment(A,R');
    trace Segment(B,R');
    trace Segment(B,P');
    trace Segment(C,P');
    trace Segment(C,Q');
        
    remplis T
	withcolor 0.8white;
    trace T 
	withpen pencircle scaled 1pt
	withcolor red;

    trace Triangle(A,B,C)
	withpen pencircle scaled 1.25
	withcolor .5green;

    RotationDeFigure(-angle(_Point(C)-_Point(B)));
    
    marque.top "A";
    marque.lft "B";
    marque.rt  "C";
    
    marque.llft "Q'";
    marque.lrt  "R'";
    marque.top  "P'";	
    
    marque.ulft "R";
    marque.bot  "P";
    marque.urt  "Q";
    
    Etiquette(
	"\begin{minipage}{6cm}\begin{center}" &
	"\textbf{Théorème de Morley}\\" &
	"Les points d'intersection des trissectrices adjacentes " &
	"d'un triangle quelconque forment un triangle équilatéral." &
	"\end{center}\end{minipage}",1,(6,-2));
endfig;

end