Fichiers de M. Chupin

Illusion d'optique...

vague-1.png
vague.mp
verbatimtex
%&latex
\documentclass{article}
\usepackage{amsmath}
\usepackage[latin1]{inputenc} 
\usepackage{xcolor}
\usepackage[charter]{mathdesign}
\begin{document}
etex
 
color vert;
color vb;
color orange;
color bleu;
 vb = 1/2 green + 1/3 blue;
 vert = 2/3red +  green ;
 orange = red + 1/3 green +1/5 blue;
 bleu = blue + 1/3 red ;
 
u:=1cm;
picture ell;
path ellt,demiell,demicercle,cercle, droite;
cercle := fullcircle scaled 0.5pt;
droite:=(-3u,0)--(3u,0);
 
ell = image(
  pickup pencircle scaled 0.5pt;
  ellt:=fullcircle xscaled (0.26u) yscaled(0.14u);
  demiell:=(halfcircle xscaled (0.3u) yscaled(0.18u))--cycle;
  fill demiell withcolor black;
  fill demiell rotated 180 withcolor white;
  fill ellt withcolor orange;
            );
j:=0.35u;
 
vague (figure 1)
beginfig(1);
 path carre;
 carre:=(-j,-j)--(17*j,-j)--(17*j,13j)--(-j,13j)--cycle;
 fill carre withcolor vb;
 for h:=0 upto 12:
  for i:=0 upto 16:
   draw ell rotated (i*30+h*30) shifted (j*i,h*j);
  endfor;
 endfor;
endfig;
 
end.
 
 

Illusion d'optique...

rond.mp vers rond.png
rond.mp
verbatimtex
%&latex
\documentclass{article}
\usepackage{amsmath}
\begin{document}
etex
 
% Déclaration de mes pictures qui permettront la composition de l'image
picture rond,rondn,rondb;
 
numeric diamax;
 
u:=1cm;
 
% Fabrication de l'image de base
 
rond = image( 
    for i:=15 downto 0:
	% cercle permettant de faire la "bande circulaire"
	path cercle, cercleb;
	numeric r,rb,moy,diff;
	% le rayon du plus petit cercle
	r:=6*2.71**((i/10))*0.3*u;
	% celui du plus grand
	rb:=6*2.71**((i+1)/10)*0.3*u;
	% On sauvegarde le diamètre maximal de la figure
	if i=15:
	    diamax:=rb;
	fi;
	% rayon du cercle "médiant"
	moy:=(r+rb)/4;
	% laRgeur de la bande circulaire
	diff:=rb-r;
	cercle := fullcircle scaled (r);
	cercleb := fullcircle scaled (rb);
	% astuce permettant de palier au problèmes engendrés 
	% par "buildcycle" qui trace dans la suite un disque noir, 
	% ceci permet aussi de ne pas avoir de transparant
	fill cercleb withcolor white;
	for j:=0 step 2 until 36:
	    pair P,P',O;
	    path noir,dr,drb,p,c,d,e,f;
	    O:=(0,0);
	    % Le point où l'on fixe la première ellipse
	    P:=(moy)*(cosd(j*10+i*10),sind(j*10+10*i));
	    % Le point ou l'on fixe la deuxième ellipse
	    P':=(moy)*(cosd(10*i+(j+1)*10),sind(10*i+(j+1)*10));
	    dr:=O--(2*xpart P,  2*ypart P);
	    drb:=O--(2*xpart P',  2*ypart P');
	    % Partie noire de la bande
	    p = buildcycle(cercle,dr,cercleb,drb);
	    fill p;
	    % tracé des ellipses
	    fill fullcircle xscaled (diff/4) yscaled (diff/2)  
		rotated(90+10*j+10*i) shifted P withcolor green ;
	    fill fullcircle xscaled (diff/4) yscaled (diff/2)  
		rotated(90+10*(j+1)+10*i) shifted P' withcolor red ;
	endfor;
    endfor;
);
 
 
beginfig(-1);
    %Déclaration de la transformation de symétrie
    transform T;
    T = identity reflectedabout((diamax/2,-20),(diamax/2,20));
    % la picture symétrique
    rondn = rond transformed T;
    % remise à  l'origine
    rondb=rondn shifted (-diamax,0);
    for i:=0 upto 2:
	for j:=0 upto 3:
	    if (j mod 2)=0:
		draw rondb rotated(i*10) 
		    shifted  (j*diamax,i*diamax) ;
	    else:
		draw rond rotated(i*10) 
		    shifted  (j*diamax,i*diamax) ;
	    fi;
	endfor;
    endfor;
    for i:= 0 upto 1:
	for j:=0 upto 2:
	    if j=1:
		draw rondb rotated(i*10) 
		    shifted  (j*diamax+diamax/2,i*diamax+diamax/2) ;
	    else:
		draw rond rotated(i*10) 
		    shifted  (j*diamax+diamax/2,i*diamax+diamax/2) ;
	    fi;
	endfor;
    endfor;
endfig;
 
end
 

Tracé d'une courbe paramétrée

Pour représenter une courbe paramétrée à la main, on détermine seulement quelques points et certaines tangentes à la courbe. On peut vérifier que cela suffit aussi à un ordinateur (grâce au language metapost !). J'ai donc fait tracer le chemin, défini par une étude préalable, de la courbe paramétrée (points et tangentes).

Animation flash


trace.mp
%@Auteur: Maxime Chupin
 
verbatimtex 
%&latex 
\documentclass{article} 
\usepackage[latin1]{inputenc}
\usepackage{amsmath}
\usepackage{fourier}
\begin{document} 
etex 
 
u=3cm;
v=3;
 
trace (figure 1)
beginfig(1);
 
    %axes
    drawarrow (-1.5u,0)--(1.5u,0) withpen pencircle scaled 0.2;
    drawarrow (0,-1.5u)--(0,1.5u) withpen pencircle scaled 0.2;
 
    %unités
    draw (-2,u)--(2,u) withpen pencircle scaled 0.2;
    draw (u,-2)--(u,2) withpen pencircle scaled 0.2;
 
    %courbe
    draw (-u,-u){1,2.25}..(-0.5u,0)..(0,0.707u)..(0.5u,1u){1,0}..(1u,0){0,-1}
	..(0.5u,-1u){-1,0}..(0,-0.707u)..(-0.5u,0)..(-1u,1u){-1,2.25} 
	withcolor (0.18,0.55,0.34);
 
    %tangentes
    drawarrow (-u,-u)--(-0.9u,-0.775u)  withcolor red;
    drawarrow (0.5u,1u)--(0.8u,1u)  withcolor red;
    drawarrow (1u,0)--(1u,-0.3u)  withcolor red;
    drawarrow (0.5u,-1u)--(0.2u,-1u)  withcolor red;
 
 
    %labels
    label.lrt(btex $x$ etex,(1.3u,0));
    label.lrt(btex $y$ etex,(0,1.4u));
    label.rt(btex $1$ etex,(0,u));
    label.llft(btex $1$ etex,(u,0));
 
    label.lrt(btex $\begin{cases}x=\cos 2t\\[2mm]y=\sin 3t\end{cases}$ etex,(-0.8u,-0.8u));
 
endfig;
end