verbatimtex 
%&latex 
\documentclass{article} 
\usepackage[latin1]{inputenc} 
\begin{document} 
etex 
 
vardef affiche(expr m) = 
 picture chiffre; 
 chiffre := thelabel(decimal(m),(0,0)); 
 draw chiffre 
    scaled 2.5 
    shifted (origine+((0,6.2cm) 
    rotated (-360/n*m))) 
enddef; 
 
vardef affichem(expr m,o) = 
 picture chiffre; 
 chiffre := thelabel(decimal(m),(0,0)); 
 draw chiffre 
    scaled 1.4 
    shifted (o+((0,2cm) 
    rotated (-6*m))) 
enddef; 
 
vardef aiguille = 
 (-4,0)--(0,1)--(17,3)--(25,0)--(17,-3)--(0,-1)--cycle 
enddef;
 


beginfig(1);
    
    pair origine; 
    origine = (5.5cm,5.5cm); 
 
    n=12; 
 
    fill fullcircle scaled 15cm 
	shifted origine 
	withpen pencircle scaled 5pt withcolor (.7,.6,1); 

    draw fullcircle scaled 15cm 
	shifted origine 
	withpen pencircle scaled 5pt withcolor (0.9,0.2,0.2); 

    draw fullcircle scaled 14.5cm 
	shifted origine 
	withpen pencircle scaled 1pt ; 
 
    for i = 1 upto n: 
	draw (((6.8cm,0)--(7.2cm,0)) 
	    rotated (360/n*i+90)) 
	    shifted origine; 
    endfor 
 
    label(btex \it Lepiote etex scaled 2.3,origine+(0,3.5cm)); 
    label(btex Les Bournalières etex scaled 1.5,origine+(0,2.6cm)); 
    label(btex \TeX mélu 2002 etex scaled 1.2,origine+(0,-2.4cm)); 
 
    draw origine withpen pencircle scaled 5pt; 
    draw fullcircle scaled 13 pt shifted origine; 
 
    for i=1 upto 12: affiche(i); endfor 
 
    numeric h,m,hd,md; 
    pair om; 
 
    h = 1; 
    m = 28; 
 
    md = 90 - (m * 6); 
    hd = 90 - (h * 30) - (m/2); 
    om = origine+((3.3cm,0) rotated hd); 
 
    fill aiguille xscaled 7.7 yscaled 2 
	rotated hd shifted origine withcolor red+green; 
 
    fill fullcircle scaled 5cm shifted om withcolor .9white; 
 
    draw fullcircle scaled 5cm shifted om withcolor red+green; 
 
    draw fullcircle scaled 4.8cm shifted om; 
 
    for i=0 step 5 until 55: affichem(i,om); endfor 
 
    draw om withpen pencircle scaled 5pt; 
    draw fullcircle scaled 11 pt shifted om; 
 
    fill aiguille xscaled 2 yscaled 1 
	rotated md shifted om withcolor red+green;  
	
endfig;

end