%% Composée par B. Lang à l'aide de Gimp et de StarOffice, elle est libre;
%% il était tentant de la reproduire avec MetaPost...

verbatimtex 
%&latex 
\documentclass{article} 
\usepackage[latin1]{inputenc} 
\usepackage[frenchb]{babel} 
\begin{document} 
etex 
euro = 1cm; 
euro = 6.558franc; % valeur choisie librement ...

beginfig(1);
path rectangle; 
rectangle = (0,0) 
 --(21euro,0) 
 --(21euro,8euro) 
 --(0,8euro) 
 --cycle; 
 
fill rectangle yscaled .5 shifted (0,4euro) 
 withcolor (.85,.95,1); 
fill rectangle yscaled .5 
 withcolor (.85,1,.85); 
fill rectangle yscaled .125 shifted (0,7euro) 
 withcolor (1,1,.85); 
draw rectangle yscaled .125 shifted (0,7euro) 
 withpen pencircle scaled 2pt; 
draw rectangle withpen pencircle scaled 2pt; 
 
draw (0,4euro)--(21euro,4euro) 
 withpen pencircle scaled .75pt 
 withcolor red; 
for i=1 upto 20: 
 picture nombre; 
 nombre := thelabel(decimal(i),(0,0)); 
 draw (i*euro,4.05euro)--(i*euro,5.2euro) 
 withpen pencircle scaled 0.75pt; 
 draw nombre scaled 2.4 shifted (i*euro,5.7euro); 
endfor; 
 
for i=1 upto 13: 
 picture nombre; 
 numeric n,p; 
 nombre := thelabel(decimal(10*i),(0,0)); 
 n := i*franc*10; 
 p := n - 5franc; 
 draw (p,3.95euro) -- (p,3.05euro) 
 withpen pencircle scaled 0.75pt; 
 draw (n,3.95euro) -- (n,2.8euro) 
 withpen pencircle scaled 0.75pt; 
 draw nombre scaled 2.4 shifted (n,2.3euro); 
endfor; 
 
 
label.rt(btex \bfseries Bonne année 2002 ! soyez « Libre » etex 
 xscaled 3.3 yscaled 2,(0,7.5euro)); 
label.rt(btex \bf Francs etex 
 xscaled 3.5 yscaled 2,(0,.5euro)); 
label.lft(btex \bf Euros etex 
 xscaled 3.5 yscaled 2,(21euro,6.5euro)); 
label.lft(btex \sf \copyright etex scaled -3, 
 (20euro,1euro)) withcolor red; 
label.lft(btex \bf Copyleft etex 
 scaled 3,(18.8euro,.8euro)) withcolor red;  
endfig;
end