prologues := 1;

verbatimtex
%&latex
\documentclass{article}
\usepackage[latin1]{inputenc}
\usepackage{marvosym}
\usepackage{mflogo}
\usepackage{times}
\begin{document}
etex

color bouton,fond;
bouton = (0.35,0.5,0.8);
fond = (0.77,0.75,0.2);

vardef linkhttp@#(expr s,z,url,c) =
    picture p;
    p := thelabel@#(s,z);
    special "[ /Rect [ " & decimal ((xpart llcorner p) -2) & " " &
        decimal((ypart llcorner p)-2) & " " &
        decimal ((xpart urcorner p)+2) & " " &
        decimal ((ypart urcorner p)+2) & " ] " & 
        "/Border [ 0 0 0 ] " &
        "/Action << /Subtype /URI /URI (" & url & ") >> " &
        "/Subtype  /Link /ANN pdfmark";
    draw p withcolor c;
enddef;

vardef cadre(expr xmin,ymin,xmax,ymax,r) =
    numeric t;
    t = 1-1/sqrt(2);
    ((xmin,ymin) + (0,r)) -- ((xmin,ymax) - (0,r)){dir 90}  
	    .. ((xmin,ymax) + t*(r,-r)) .. {dir 0} 
     ((xmin,ymax) + (r,0)) -- ((xmax,ymax) - (r,0)){dir 0}   
	    .. ((xmax,ymax) - t*(r,r))  .. {dir 270}
     ((xmax,ymax) - (0,r)) -- ((xmax,ymin) + (0,r)){dir 270} 
	    .. ((xmax,ymin) + t*(-r,r)) .. {dir 180}
     ((xmax,ymin) - (r,0)) -- ((xmin,ymin) + (r,0)){dir 180} 
	    .. ((xmin,ymin) + t*(r,r)) ..  {dir 90}cycle;
enddef;
                                                                    
                                                                    
beginfig(1);

fill (0,0)--(0,450)--(600,450)--(600,0)--cycle withcolor fond;

path c[];
c1 = (184,5)--(584,5)--(584,405)--(184,405)--cycle;
c2 = (32,375)--(132,375)--(132,275)--(32,275)--cycle;
c3 = (0,0)--(120,0)--(120,18)--(0,18)--cycle;
c4 = (20,5)--(144,5)--(144,380)--(20,380)--cycle;

draw (16,410)--(584,410) 
	withcolor (0.5white-fond) 
	withpen pencircle scaled 2pt;

label(btex \textbf{Syracuse} etex xscaled 10 yscaled 5 ,(300,425)) 
	withcolor 0.9*fond;

labeloffset := 0;
label.rt(btex \bf 
	    Exploration de l'ensemble de Mandelbrot 
	 etex scaled 3,(16,427)) 
	 withcolor 0.6red; 

fill cadre(16,120,148,390,5) 
	withcolor 0.9fond;

draw cadre(16,120,148,390,5) 
	withpen pencircle scaled 1.5pt 
	withcolor 0.6fond;

fill c1 withcolor white;
fill c2 withcolor white;

label(btex \large Chargement en cours... etex,(384,205));

label(btex \large Calcul en cours... etex,(82,325));

label(btex \begin{minipage}{120pt}
		\begin{center}
		    -- 9 mai 2004 --\\
		    Jean-Michel Sarlat
		\end{center}
	    \end{minipage} etex scaled 1.2, (82,60)) 
	withcolor (black -0.6fond);
endfig;
end