input geometriesyr16;
figure(0,0,6u,6u);
pair A,B,C;
A=u*(1,1);
C-A=u*(4,0);
B=pointarc(cercles(iso(A,C),C),50);
trace triangle(A,B,C);
trace codeperp(C,B,A,8);
nomme.lft(A);
nomme.rt(C);
nomme.top(B);
fin;
figure(0,u,7u,5u);
pair A,B,C,M,N;
A=u*(4,3);
B-A=u*(2,-0.75);
C-A=u*(1.5,1);
M=12/5[B,A];
N=12/5[C,A];
trace droite(A,B);
trace droite(A,C);
trace droite(M,N);
trace droite(B,C);
trace marque_para(droite(M,N),droite(B,C),0.48);
nomme.top(A);
nomme.llft(B);
nomme.lft(C);
nomme.llft(M);
nomme.lft(N);
fin;
u:=7mm;
figure(0,0,9u,5u);
pair A,B,C;
A=u*(1,1);
B-A=u*(7,0);
C-B=u*(0,3);
trace triangle(A,B,C);
trace codeperp(A,B,C,8);
trace appelation(A,C,2mm,btex Hypot\'enuse etex);
trace appelation(A,B,-2mm,btex c\^ot\'e adjacent \`a $\alpha$ etex);
trace appelation(B,C,-2mm,btex c\^ot\'e oppos\'e \`a $\alpha$ etex);
trace Codeangle(B,A,C,0,btex $\alpha$ etex);
fin;
figure(0,0,7.5u,4.5u);
pair A,B,C,D,E;
C=u*(0.75,0.25);
D-C=u*(2,2);
E-C=u*(-0.25,2.5);
A-C=u*(3,0.25);
B-A=u*(-1,3);
marque_p:="croix";
nomme.rt(A);
nomme.rt(B);
marque_p:="non";
trace droite(A,B);
trace triangle(C,D,E);
trace symetrie(triangle(C,D,E),A,B);
trace segment(C,symetrie(C,A,B)) dashed evenly;
trace codeperp(B,iso(C,symetrie(C,A,B)),symetrie(C,A,B),8);
trace Codelongueur(C,iso(C,symetrie(C,A,B)),iso(C,symetrie(C,A,B)),symetrie(C,A,B),2);
fin;
u:=5mm;
figure(0,0,7.5u,4.5u);
pair O,C,D,E;
C=u*(0.75,0.75);
D-C=u*(2,1);
E-C=u*(1,3);
O-C=u*(3,1.5);
marque_p:="croix";
nomme.top(O);
trace triangle(C,D,E);
trace symetrie(triangle(C,D,E),O);
trace segment(E,symetrie(E,O)) dashed evenly;
trace Codelongueur(E,iso(E,symetrie(E,O)),iso(E,symetrie(E,O)),symetrie(E,O),2);
fin;
figure(0,0,7.5u,4.5u);
pair A,B,C,D,E;
C=u*(0.75,0.5);
D-C=u*(2,1);
E-C=u*(1,3);
A-C=u*(0.5,-0.25);
B-A=u*(3.5,0.5);
trace triangle(C,D,E);
trace triangle(C,D,E) shifted(B-A);
trace segment(E,E+B-A) dashed evenly;
drawarrow A--B withpen pensquare scaled 1.25bp;
nomme.lft(A);
nomme.lrt(B);
fin;
figure(0,0,7.5u,7u);
pair O,C,D,E;
C=u*(3.75,0.25);
D-C=u*(2,1);
E-C=u*(1,3);
O-C=u*(-3,2.25);
trace triangle(C,D,E);
trace rotation(triangle(C,D,E),O,50);
trace chemin(C,O,rotation(C,O,50)) dashed evenly;
trace Codeangle(C,O,rotation(C,O,50),0,btex 50 etex);
marque_p:="croix";
nomme.lft(O);
fin;
u:=1cm;
figure(0,0,5u,3u);
pair A,B,C;
A=u*(0.75,0.75);
B-A=u*(2,1);
C-B=u*(1,-0.5);
drawarrow A--B;
drawarrow B--C;
drawarrow A--C withpen pensquare scaled 1.5bp;
nomme.lft(A);
nomme.top(B);
nomme.rt(C);
trace appelation(A,B,3mm,btex $\overrightarrow{\strut AB}$ etex);
trace appelation(B,C,3mm,btex $\overrightarrow{\strut BC}$ etex);
trace appelation(A,C,-4mm,btex $\overrightarrow{\strut AB}+\overrightarrow{\strut BC}$ etex);
fin;
figure(0,0,5u,4u);
pair A,B,C,D;
A=u*(1.25,3.25);
B-A=u*(3.15,-0.25);
C-A=u*(-1,-1.5);
D-C=B-A;
drawarrow A--B;
drawarrow A--C;
drawarrow A--D withpen pensquare scaled1.5bp;
trace chemin(C,D,B) dashed evenly;
nomme.ulft(A);
nomme.urt(B);
nomme.llft(C);
nomme.lrt(D);
trace appelation(A,B,3mm,btex $\overrightarrow{\strut AB}$ etex);
trace appelation(A,C,-4mm,btex $\overrightarrow{\strut AC}$ etex);
trace appelation(A,D,2.5mm,btex $\overrightarrow{\strut AB}+\overrightarrow{\strut AC}$ etex);
fin;
end