verbatimtex
%&latex
\documentclass{article}
\input christ5.tex
\begin{document}
etex
%%
input geometriesyr;
figure(0,0,11u,8u);
pair A,B,C,D,E,F,G,H;
A=u*(1,1);
C=u*(3,2);
E=u*(4,5);
G=u*(2,3.5);
trace A--C--E--G--cycle;
B=u*(6,1.5);
D-C=B-A;
F-E=B-A;
H-G=B-A;
trace B--D--F--H--cycle;
drawarrow A--B withcolor orange;
drawarrow C--D withcolor orange;
drawarrow E--F withcolor orange;
drawarrow G--H withcolor orange;
label.bot(btex $\vecteur{\strut AB}$ etex,iso(A,B));
nomme.llft(A);
nomme.bot(B);
nomme.urt(C);
nomme.urt(D);
nomme.top(E);
nomme.top(F);
nomme.ulft(G);
nomme.ulft(H);
fin;
figure(0,0,7u,5u);
pair C,V,M,L;
C=u*(1,1);
V=u*(2,3);
L=u*(5,1.25);
M-L=V-C;
drawarrow C--V withcolor rouge;
drawarrow L--M withcolor rouge;
trace V--M dashed evenly;
trace C--L dashed evenly;
nomme.llft(C);
nomme.lrt(L);
nomme.rt(M);
nomme.lft(V);
fin;
figure(0,0,7u,7u);
pair E,F,G,H,I,J;
E=u*(1,3);
F=u*(2,5);
G=u*(4,6);
H-G=E-F;
I=u*(5,2);
J-I=G-H;
trace F--G--H--E;
trace H--I;
trace J--G;
trace E--F--J--I--cycle withcolor orange;
nomme.llft(E);
nomme.ulft(F);
nomme.top(G);
nomme.bot(H);
nomme.lrt(I);
nomme.urt(J);
fin;
u:=0.9cm;
figure(0,-3u,10u,7u);
pair A,B,E,F,R,S,T;
A=u*(1,1);
B=u*(2,4.5);
E=u*(5,6);
F=u*(9,4);
R=u*(4,-2);
S=u*(2.5,0.5);
T=u*(5,1);
drawarrow A--B;
drawarrow E--F;
trace R--S--T--cycle;
trace R--S--T--cycle shifted (B-A);
trace R--S--T--cycle shifted (B-A+F-E);
drawarrow S--(S+B-A);
appelation(S,S+B-A,2mm,btex $\vecteur{\strut AB}$ etex);
drawarrow (T+B-A)--(T+B-A+F-E);
appelation(T+B-A,T+B-A+F-E,2mm,btex $\vecteur{\strut EF}$ etex);
drawarrow R--(R+B-A+F-E) withcolor orange;
appelation(R,R+B-A+F-E,2mm,btex $\vecteur{\strut AB}+\vecteur{\strut EF}$ etex);
nomme.urt(B);
nomme.rt(F);
label(btex $\cal F$ etex,iso(R,S,T));
label(btex ${\cal F}_1$ etex,iso(R,S,T) shifted(B-A));
label(btex ${\cal F}_2$ etex,iso(R,S,T) shifted(B-A+F-E));
marque_p:="croix";
nomme.llft(A);
nomme.lft(E);
marque_p:="non";
fin;
u:=1cm;
figure(0,0,7u,4u);
pair A,B,C;
A=u*(1,0.75);
C=u*(3,3.25);
B=u*(6,2);
drawarrow A--B withcolor orange;
drawarrow A--C;
drawarrow C--B;
appelation(A,B,2mm,btex $\vecteur{\strut AC}+\vecteur{\strut CB}$ etex);
nomme.llft(A);
nomme.top(C);
nomme.lrt(B);
fin;
u:=0.8cm;
figure(0,0,8u,5u);
pair I,J,K,L;
I=u*(1,0.75);
K=u*(2.5,3.25);
J=u*(6,2);
L-K=J-I;
drawarrow I--J;
drawarrow I--K;
drawarrow I--L withcolor orange;
draw K--L--J dashed evenly;
appelation(I,L,2mm,btex $\vecteur{\strut IJ}+\vecteur{\strut IK}$ etex);
nomme.llft(I);
nomme.top(K);
nomme.lrt(J);
nomme.top(L);
fin;
u:=1cm;
figure(0.25u,0,5.5u,7u);
trace feuillet withcolor blanc;
pair A,B,E,F,O;
A=u*(0.75,2);
B=u*(1.75,5);
drawarrow A--B;
O=u*(2,2);
E=u*(4,6.25);
F=u*(5.25,4.25);
drawarrow E--F;
marque_p:="croix";
nomme.bot(O);
nomme.lft(A);
nomme.top(E);
marque_p:="non";
nomme.top(B);
nomme.bot(F);
drawarrow O--(O+B-A) withcolor violet;
appelation(O,O+B-A,2mm,btex $\vecteur{\strut AB}$ etex);
drawarrow O--(O+F-E) withcolor violet;
appelation(O,O+F-E,2mm,btex $\vecteur{\strut EF}$ etex);
drawarrow O--(O+F-E+B-A) withcolor orange;
appelation(O,O+B-A+F-E,2mm,btex $\vecteur{\strut AB}+\vecteur{\strut EF}$ etex);
trace (O+B-A)--(O+B-A+F-E)--(O+F-E) dashed evenly;
fin;
figure(0.25u,0,5.5u,7u);
trace feuillet withcolor blanc;
pair A,B,E,F,O;
A=u*(0.75,2);
B=u*(1.75,5);
drawarrow A--B;
O=u*(2,2);
E=u*(4,6.25);
F=u*(5.25,4.25);
drawarrow E--F;
marque_p:="croix";
nomme.bot(O);
nomme.lft(A);
nomme.top(E);
marque_p:="non";
nomme.top(B);
nomme.bot(F);
drawarrow O--(O+B-A) withcolor violet;
appelation(O,O+B-A,2mm,btex $\vecteur{\strut AB}$ etex);
drawarrow (O+B-A)--(O+F-E+B-A) withcolor violet;
appelation(O+B-A,O+F-E+B-A,2mm,btex $\vecteur{\strut EF}$ etex);
drawarrow O--(O+F-E+B-A) withcolor orange;
appelation(O,O+B-A+F-E,2mm,btex $\vecteur{\strut AB}+\vecteur{\strut EF}$ etex);
fin;
figure(0,0,5u,8u);
pair A,B,C,D,E;
A=u*(0.75,2.5);
B=u*(1.75,4.25);
C=u*(2.75,3.5);
D-A=C-B;
E-C=B-A;
trace A--B--E--C--D--cycle;
trace B--C--A;
nomme.lft(A);
nomme.top(B);
nomme.top(E);
nomme.rt(C);
nomme.lrt(D);
fin;
end