Fichier figure058.mp (figure 1) — Modifié le 10 Avril 2008 à 23 h 05

figure058.mp (figure 1)
Source

%@AUTEUR:Guillaume Connan
prologues:=2;

verbatimtex
%&latex
\documentclass{article}
\begin{document}
etex

input courbes;
input geo;

color vert_e, turquoise, orange, vert_fonce, rose, vert_mer, bleu_ciel, or, rouge_v,bleu_m,bleu,bleu_f;
vert_e:=(0,0.790002,0.340007);
turquoise:=(0.250999,0.878399,0.815699);
orange:=(0.589999,0.269997,0.080004);
vert_fonce:=(0,1.4*0.392193,0);
rose:=(1.0, 0.752907, 0.796106);
bleu_ciel:=(1.2*0.529405,1.2*0.807794,1);%.2*0.921598);
or:=(1,0.843104,0);
rouge_v:=(0.829997,0.099994,0.119999);
bleu_m:=(0.7*0.529405,0.7*0.807794,0.7);%*0.921598);
bleu_f:=(0.211762,0.3231176,0.3686392);
bleu:=(0.529405,0.807794,1);

%INTEG FONCTION De LA BORNE SUP

% Déclarations des constantes %
numeric xmin, xmax, ymin, ymax, N;

ux:=1cm;  uy:=1cm;
xmin := -.5 ; xmax := 9;
ymin := -1.5 ; ymax := 3;

pair d,h;
d:=(.1*ux,0);
h:=(0,.1*uy);

% Définitions des axes et labels associés
vardef axes =
  drawarrow (xmin*ux,0) -- (ux*xmax,0) ; % axe des x
  drawarrow (0,ymin*uy) -- (0,uy*ymax); % axe des y
  label.rt(btex $x$ etex,(xmax*ux,0)); % label de l'axe des x
  label.urt(btex $y$ etex,(0,ymax*uy)); % label de l'axe des y
enddef;


beginfig(1);
  pair A,B; A:=(-0.5*ux,-uy); B:=(7*ux,3*uy);
  
  path C; C:=A{dir10}..B{dir10};
  
  pair a,b; a:=A yscaled 0; b:=B yscaled 0;

  pair M,m; M:= point .8 of C; m:=M yscaled 0;
  
  path U; U:=(0,0)--(5*ux,0);
  
  pair X; X:= C intersectionpoint U;
  
  path V,K,W; V:=M--m; K:=m--X; W:=buildcycle(C,V,K);

  path Y,Z; Y:=A--a--X; Z:=buildcycle(C,reverse Y);

  fill W withcolor bleu; fill Z withcolor bleu;

% tracés
  axes;
  pickup  pencircle scaled 1.3bp;
  draw C withcolor bleu_f; label.rt(btex $y=f(x)$ etex,B shifted d)withcolor 0.3white;
  
  draw (A--a)  withcolor 0.3white; draw (B--b)  withcolor 0.3white;
  
  draw a--(a shifted h); label.top(btex $a$ etex,a shifted h); draw (b shifted h)--(b shifted -h); label.bot(btex $b$ etex,b shifted -h);
  
  draw (M--m)  withcolor 0.3white;
  
  draw (m shifted h)--(m shifted -h); label.bot(btex $t$ etex,m shifted -h);
  
  label.rt(btex $\displaystyle\int_a^tf(u)du$ etex, (X+m)/2 shifted (-0.31ux,0.75*uy));
  
endfig;
end