input svgnames;

%% === style.mp ----------------------------------------------------------------
picture UnBeauPoint;
UnBeauPoint := image(
    fill fullcircle scaled 3pt;
    fill fullcircle scaled 2pt withcolor red+green;
);
vardef pointe expr p = draw UnBeauPoint shifted p; enddef;
%% =

%% === tangentes.mp ------------------------------------------------------------
vardef petiteTangente(expr p, t) =
   save v; pair v;
   v = 0.7 * (direction t of p);
   (-v--v) shifted (point t of p)
enddef;
%% =


%% === mp-garamond.mp ----------------------------------------------------------
verbatimtex
%&latex
\documentclass{minimal}
\usepackage[garamond]{mathdesign}
\begin{document}
etex
%% =

u := 1cm;

path p,q;
p = ((1,-1)..(3,2)..(4.7,6)) scaled u ;
q = p reflectedabout (origin,(10,10));

pair M, N, M', N';
M = point 1 of p;
N = point 1 of q;
M'= (xpart M,0);
N'= (xpart N,0);



u := 1cm;


beginfig(1);



  drawarrow ((-3,0)--(7,0)) scaled u;
  drawarrow ((0,-3)--(0,7)) scaled u;

  draw ((-3,-3) -- (7,7)) scaled u withcolor CornflowerBlue;

  draw p withpen pencircle scaled 1.5 withcolor SandyBrown;
  draw q withpen pencircle scaled 1.5 withcolor Crimson;
  draw petiteTangente(p,1) withpen pencircle scaled 0.5 withcolor Olive;
  draw petiteTangente(q,1) withpen pencircle scaled 0.5 withcolor Olive;

  draw M'--M--N--N' dashed evenly;

  label.ulft(btex $M$ etex, N);
  label.lrt(btex $N$ etex,M);

  dotlabel.lrt (btex $O$ etex, origin);
  dotlabel.lrt  (btex \phantom{f}$x$ etex, N');
  dotlabel.lrt  (btex $f^{-1}(x)$ etex, M');

  label.top (btex $y=f(x)$ etex, point 2 of p);
  label.rt (btex $y=f^{-1}(x)$ etex, point 2 of q);
  label.lrt (btex $y=x$ etex, (6,6) scaled u) withcolor CornflowerBlue;
  pointe M;
  pointe N;

endfig;

end