%@AUTEUR: Jean-Michel Sarlat
%@DATE: 12 octobre 2009

%% === style.mp ----------------------------------------------------------------
picture UnBeauPoint;
UnBeauPoint := image(
    fill fullcircle scaled 3pt;
    fill fullcircle scaled 2pt withcolor red+green;
);
vardef pointe expr p = draw UnBeauPoint shifted p; enddef;
%% =

%% === mp-garamond.mp ----------------------------------------------------------
verbatimtex
%&latex
\documentclass{minimal}
\usepackage[garamond]{mathdesign}
\begin{document}
etex
%% =


pair A,B,C,X[],Y[],Z[];


u = 0.85cm;

B = (0,0);
A = (2u,0.3u);
C = (0,-4u);

X4 = B rotatedaround(A,-90);
X3 = A rotatedaround(B,90);
Z4 = A rotatedaround(C,-90);
Z3 = C rotatedaround(A,90);
Y4 = C rotatedaround(B,-90);
Y3 = B rotatedaround(C,90);

Z2 = X4 rotatedaround(Z3,-90);
X1 = Z3 rotatedaround(X4,90);
Y2 = Z4 rotatedaround(Y3,-90);
Z1 = Y3 rotatedaround(Z4,90);
X2 = Y4 rotatedaround(X3,-90);
Y1 = X3 rotatedaround(Y4,90);

labeloffset := 7;


beginfig(1);

  draw B--X3--X4--A;
  draw A--Z3--Z4--C;
  draw C--Y3--Y4--B;
  draw X4--X1--Z2--Z3--cycle;
  draw Z4--Z1--Y2--Y3--cycle;
  draw Y4--Y1--X2--X3--cycle;
  
  drawoptions(withcolor 0.95white);
  fill A--B--C--cycle;
  fill X1--X2--X3--X4--cycle;
  fill Y1--Y2--Y3--Y4--cycle;
  fill Z1--Z2--Z3--Z4--cycle;
  
  drawoptions();
  for i:= 1 upto 2:
    draw ((i/4)[X1,X2])--X4;
    draw ((i/4)[Y1,Y2])--Y4;
    draw ((i/4)[Z1,Z2])--Z4;
  endfor;
  for i:= 1 upto 2:
    draw ((i/4)[X2,X1])--X3;
    draw ((i/4)[Y2,Y1])--Y3;
    draw ((i/4)[Z2,Z1])--Z3;
  endfor;
  
  drawoptions(withpen pencircle scaled 1.5);
  draw A--B--C--cycle;
  draw X1--X2--X3--X4--cycle;
  draw Y1--Y2--Y3--Y4--cycle;
  draw Z1--Z2--Z3--Z4--cycle;
  
  for i:=1 upto 4:
    pointe X[i];
    pointe Y[i];
    pointe Z[i];
  endfor;

  pointe A;
  pointe B;
  pointe C;
  
  drawoptions(withcolor (0.5,0.2,0.2));
  label.ulft(btex $B$ etex scaled 1.3,B);
  label.urt(btex $A$ etex scaled 1.3,A);
  label.llft(btex $C$ etex scaled 1.3,C);

  label.lft(btex $A_3$ etex scaled 1.3, X3);
  label.rt(btex $A_4$ etex scaled 1.3, X4);
  label.ulft(btex $A_2$ etex scaled 1.3, X2);
  label.top(btex $A_1$ etex scaled 1.3, X1);

  label.lrt(btex $B_3$ etex scaled 1.3, Y3);
  label.urt(btex $B_4$ etex scaled 1.3, Y4);
  label.llft(btex $B_2$ etex scaled 1.3, Y2);
  label.lft(btex $B_1$ etex scaled 1.3, Y1);
  
  label.top(btex $C_3$ etex scaled 1.3, Z3);
  label.llft(btex $C_4$ etex scaled 1.3, Z4);
  label.rt(btex $C_2$ etex scaled 1.3, Z2);
  label.rt(btex $C_1$ etex scaled 1.3, Z1);
  
endfig;

end