Ces fonctions et macros créent un élément graphique au moment de leur évaluation et renvoient un résultat égal à Nil, elles ne sont utilisables que lors de la création d’un élément graphique "Utilisateur"1.
Elles peuvent être utilisées dans des macros, mais elles ne seront évaluées que si ces macros sont exécutées lors de la création d’un élément graphique "Utilisateur".
Notations:
<argument>: signifie que l’argument est obligatoire.
[, argument]: signifie que l’argument est facultatif.
Axes( <origine>, <graduationX + i*graduationY> [, position label origine] ).
Description : dessine les axes, <origine> est l’affixe du point d’intersection des axes, <graduationX> est le pas pour les graduations sur l’axe Ox, et <graduationY> celui de l’axe Oy, une graduation égale à zéro signifie l’absence de graduation. La longueur des graduations est dans la variable globale xyticks que l’on peut modifier, la distance des labels à l’extrêmité des graduations est dans la variable xylabelsep qui peut également être modifiée.
Le troisième paramètre est facultatif, il permet de préciser la position des labels de l’origine (à l’intersection des axes), c’est un complexe: a + ib, la partie réelle concerne l’abscisse de l’origine et l’autre concerne l’ordonnée. Ces deux nombres peuvent prendre trois valeurs:
0: le label n’apparaît pas,
1: le label est affiché comme celui des autres graduations,
2: le label est décalé pour ne pas chevaucher l’autre axe (valeur par défaut).
On peut modifier dans les Attributs: le style de ligne, l’épaisseur, la couleur et la taille des labels.
view(-5,4,-5,5),Marges(0.5,0,0,0.5), size(7.5), Width:=2, Color:=lightgray, Grille(-5-5*i,(1+i)/2), Width:=4, Color:=gray, Grille(-5-5*i,(1+i)), Color:=black, Arrows:=1, Axes(-5-5*i,1+i,1+i),Arrows:=0, LabelAxe(x,-pi-5*i," - π",2-i,1), LabelAxe(x,pi-5*i,"π",2+i,1), SaveAttr(), FillStyle:=full, FillColor:=lightblue, FillOpacity:=0.5, domaine2(3*sin(x)^3, -5,-pi,pi), RestoreAttr(), Color:=red, Arrows:=0, Width:=8, Cartesienne( 3*sin(x)^3 )
Bezier( <liste de points> ).
Description : dessine une succession de courbes de {Bezier} (avec éventuellement des segments de droite). Il y a plusieurs possibilités pour la liste de points:
une liste de trois points [A, C, B], il s’agit alors d’une courbe de Bezier d’origine <A> et d’extrémité <B> avec un point de contrôle <C>, c’est la courbe paramétrée par:
(1 - t)2A + 2t(1 - t)C + t2B
une liste de 4 points ou plus: [A1, C1, C2, A2, C3, C4, A3...]: il s’agit alors d’une succession de courbes de Bezier à 2 points de contrôles, la première va de A1 à A2, elle est contrôlée par C1, C2 (paramétrée par (1 - t)3tA1 + 3(1 - t)2tC1] + 3(1 - t)t2C2 + t3A2), la deuxième va de A2 à A3 et est contrôlée par C3,C4 ...etc. Une exception toutefois, on peut remplacer les deux points de contrôle par la constante jump, dans ce cas on saute directement de A1 à A2 en traçant un segment de droite.
Le nombre de points calculés (par courbe) est modifiable dans les Attributs (variable NbPoints).
view(-4,4,-4,5),Marges(0,0,0,0), size(7.5), Width:=8, A:=-3+4*i, B:=3+i, C:=3-3*i, D:=-3-3*i, C1:=4.5*i,C2:=-2*i, C3:=2-i, C4:=-2, FillStyle:=full, FillColor:=lightblue,Color:=red, Bezier(A,C1,C2,B,jump,C,C3,C4,D,jump,A), FillStyle:=none, DotStyle:=cross, DotScale:=2,Color:=black, LabelDot(A,"A","N",1), LabelDot(B,"B","E",1), LabelDot(C,"C","SE",1), LabelDot(D,"D","SO",1), LabelDot(C1,"C1","E",1), LabelDot(C2,"C2","SO",1), LabelDot(C3,"C3","N",1), LabelDot(C4,"C4","N",1), LineStyle:=userdash, DashPattern:=[5,2,0.5,2], Width:=6, LineCap:=round, Ligne([A,C1,C2,B,jump,C,C3,C4,D],0)
Cartesienne( <f(x)> [, n, 1] ).
Description : trace la courbe cartésienne d’équation y = f(x). Le paramètre optionnel <n> est un entier (égal à 5 par défaut) qui permet de faire varier le pas de la manière suivante: lorsque la distance entre deux points consécutifs est supérieur à un certain seuil alors on calcule un point intermédiaire [par dichotomie], ceci peut être répété n fois. Si au bout de n itérations la distance entre deux points consécutifs est toujours supérieure au seuil, et si la valeur optionnelle 1 est présente, alors une discontinuité (jump) est insérée dans la liste des points.
view(-2,2,-0.1,2),Marges(0.5,0.5,0.5,0.5), size(7.5), tMin:=-2, tMax:=2, Color:=darkgray, Width:=8, LineStyle:=dotted, Grille(0,0.5*(1+i)), Color:=black, LineStyle:=solid,Axes(0,1+i,1), NbPoints:=100, Width:=8, Color:=darkseagreen, Cartesienne(x*Ent(1/x),5,1)
Courbe( <f(t)> [, n, 1] ).
Description : trace la courbe paramétrée par <f(t)> où f est à valeurs complexes.
Le paramètre optionnel <n> est un entier (égal à 5 par défaut) qui permet de faire varier le pas de la manière suivante: lorsque la distance entre deux points consécutifs est supérieur à un certain seuil alors on calcule un point intermédiaire (par dichotomie), ceci peut être répété n fois. Si au bout de n itérations la distance entre deux points consécutifs est toujours supérieure au seuil, et si la valeur optionnelle 1 est présente, alors une discontinuité (jump) est insérée dans la liste des points.
Droite( <A>, <B> [, C] ).
Description : trace la droite (AB) lorsque le troisième argument <C> est omis, sinon c’est la droite d’équation cartésienne <A>x+<B>y=<C>.
view(-5,5,-5,5),Marges(0,0,0,0), size(7.5), F:=sqrt(7), F’:=-F, {foyers} Width:=1, Color:=darkgray, for t from -pi to pi step 0.1 do M:=4*cos(t)+3*i*sin(t), Vn:=(M-F)/abs(M-F)+(M-F’)/abs(M-F’), Droite(M,M+Vn),{normale à l’ellipse} od, Width:=8, Color:=red, Ellipse(0,4,3), LabelDot(F,"F","S",1), LabelDot(F’,"Fʹ","S",1)
Ellipse( <A>, <Rx>, <Ry> [, inclinaison] ).
Description : trace une ellipse de centre <A> de rayons <Rx> et <Ry> sur les axes respectifs Ox et Oy. Le dernier paramètre <inclinaison> est un angle en degrés (nul par défaut) qui indique l’inclinaison de l’ellipse par rapport à l’horizontale.
view(-5.25,5.25,-5.25,5.25), Marges(0,0,0,0), size(7.5), background(full,blue), Width:=4, Color:=white, inclin:=[0,35,-35], for z in inclin do Ellipse(0,5,2,z) od, Width:=2*mm, Ellipse(0,1.5,4.5), Label(-0.1, "{6cm} {3.5cm} {R T F}")
EllipticArc( <B>, <A>, <C>, <Rx>, <Ry> [, sens] ).
Description : trace un arc d’ellipse dont les axes sont Ox et Oy et le centre <A>, le rayon sur Ox est <Rx>, et celui sur Oy est <Ry>. L’arc est tracé partant de la droite (AB) jusqu’à la droite (AC), l’argument facultatif <sens> indique: le sens trigonométrique si sa valeur est 1 (valeur par défaut), le sens contraire si sa valeur est - 1.
view(-2.25,3.75,-2,5),Marges(0,0,0,0),size(7.5), A:=0, B:=3+i, C:=2+4*i, DotScale:=2, Width:=8, Ligne([B,A,C],0), Color:=red, LabelDot(A,"A","S",1), LabelDot(B,"B","N",1), LabelDot(C,"C","SE",1), Arrows:=1, Color:=blue, EllipticArc(B,A,C,2,1,-1), EllipticArc(B,A,C,2,3,1)
Remarque: pour un arc de cercle, il suffit de prendre <Rx> et <Ry> égaux. Mais le plus simple est d’utiliser la macro Arc qui remplace la commande Arc de l’ancienne version.
EquaDif( <f(t,x,y)>, <t0>, <x0 + i*y0> [, mode] ).
Description : trace une solution approchée de l’équation différentielle: xʹ(t) + iyʹ(t) = f(t, x, y) avec la condition initiale x(t0) = x0 et y(t0) = y0. Le dernier paramètre est facultatif et peut valoir 0, 1 ou 2:
<mode>=0: la courbe représente les points de coordonnées (x(t), y(t)), c’est la valeur par défaut.
<mode>=1: la courbe représente les points de coordonnées (t, x(t)).
<mode>=2: la courbe représente les points de coordonnées (t, y(t)).
C’est la méthode de {Runge-Kutta} d’ordre 4 qui est utilisée.
Exemple(s) : l’équation xʹʹ - xʹ - tx = sin(t) avec la condition initiale x(0) = - 1 et xʹ(0) = 1 / 2, se met sous la forme:
$\begin{pmatrix}
X'\\Y'\end{pmatrix}=\begin{pmatrix} 0&1\\t&1\end{pmatrix}\begin{pmatrix}X\\Y\end{pmatrix}+
\begin{pmatrix}0\\\sin(t)\end{pmatrix}$
en posant X = x et Y = xʹ:
view(-10.5,2.5,-1.5,4.5),Marges(0,0,0,0), size(7.5,0), Arrows:=1, Width:=4, Axes(0,1+i), Arrows:=0, LabelAxe(y,4.25*i,"x"), LabelAxe(x,2,"t",2), Width:=8, Color:=red, tMin:=-10, tMax:=2, EquaDif(y+i*(t*x+y+sin(t)),0,-1+i/2, 1), Color:=black, LabelStyle:=stacked, Label(-6+2*i, "xʹʹ - txʹ - x = sin(t)
avec x(0) = - 1 et $x'(0)=\frac12$")
Grille( <origine>, <graduationX + i*graduationY> ).
Description : dessine une grille, <origine> est l’affixe du point considéré comme origine, <graduationX> est le pas des graduations sur l’axe Ox, et <graduationY> celui de l’axe Oy, une graduation égale à zéro signifie l’absence de graduation.
On peut modifier dans les Attributs le style de ligne, l’épaisseur et la couleur. La grille de ne fait pas appraître de graduations, on peut dessiner des axes par dessus.
Implicit( <f(x,y)> [, n, m] ).
Description : trace la courbe implicite d’équation f(x, y) = 0. L’intervalle des abscisses est subdivisé en <n> parties et l’intervalle des ordonnées en <m> parties, par défaut n = m = 25. Sur chaque pavé ainsi obtenu on teste s’il y a un changement de signe, auquel cas on applique une dichotomie sur les bords du pavé.
view(-5,5,-5,5),Marges(0,0,0,0), size(7.5), Arrows:=1, Width:=4, Axes(0,1+i), Arrows:=0, Width:=8, Color:=red, Implicit( sin(x*y) )
Label( <affixe1>, <texte1>,..., <affixeN>, <texteN> ).
Description : place la chaîne de caractères <texte1> à la position <affixe1> ... etc. Les paramètres <texte1>,..., <texteN> sont donc interprétés comme des chaînes de caractères.
view(-5,5,-5,5),Marges(0,0,0,0), size(7.5,0), C:=Cube(Origin, M(3,3,0)), S:=Sommets(C), Point3D(S), DrawPoly(C,0), k:=0, for Z in S by 2 do Inc(k,1), Label(Proj3D(Z)+ if k>4 then 0.5*i else -0.5*i fi, ["$S_",k,"$"]) od
Ligne( <liste>, <fermée> [, rayon] ).
Description : trace la ligne polygonale définie par la liste, si le paramètre <fermée> vaut 1, la ligne polygonale sera fermée, si sa valeur est 0 la ligne est ouverte. Si l’argument <rayon> est précisé (0 par défaut), alors les "angles" de la ligne polygonale sont arrondis avec un arc de cercle dont le rayon correspond à l’argument <rayon>.
Marges(0,0,0,0), size(7.5), A:=-5-5*i, B:=5*i, C:=5-5*i,niv:=6, Tr:=[A,B,C,jump], {initial} for k from 1 to niv do Tr:=[hom(Tr,A,0.5),hom(Tr,B,0.5), hom(Tr,C,0.5)] od, FillStyle:=full,FillColor:=blue, Ligne(Tr,1)
Path( <liste> [, fermé (0/1)]
Description : trace le chemin représenté par <liste> et ferme la dernière composante de celui-ci si l’argument optionnel vaut 1 (sa valeur par défaut est 0). La liste est une succession de points (affixes) et d’instructions indiquant à quoi correspondent ces points, ces instructions sont:
line: relie les points par une ligne polygonale,
linearc: relie les points par une ligne polygonale mais les angles sont arrondis par un arc de cercle, la valeur précédent la commande linearc est interprétée comme le rayon de ces arcs.
arc: dessine un arc de cercle, ce qui nécessite quatre arguments: 3 points et le rayon, plus éventuellement un cinquième argument: le sens (+/- 1), le sens par défaut est 1 (sens trigonométrique).
ellipticArc: dessine un arc d’ellipse, ce qui nécessite cinq arguments: 3 points, le rayonX, le rayonY, plus éventuellement un sixième argument: le sens (+/- 1), le sens par défaut est 1 (sens trigonométrique), plus éventuellement un septième argument: l’inclinaison en degrés du grand axe par rapport à l’horizontale.
curve: relie les points par une spline cubique naturelle.
bezier: relie le premier et le quatrième point par une courbe de bézier (les deuxième et troisième points sont les points de contrôle).
circle: desine un cercle, ce qui necessite deux arguments: un point et le centre, ou bien trois arguments qui sont trois points du cercle.
ellipse: dessine une ellipse, les arguments sont: un point, le centre, rayon rX, rayon rY, inclinaison du grand axe en degrés par rapport à l’horizontale (facultatif).
move: indique un déplacement sans tracé.
closepath: ferme la composante en cours.
Par convention, le premier point du tronçon numéro n+1 est le dernier point du tronçon numéro n.
Exemple(s) :
view(-5,5,-4,6),Marges(0,0,0,0),size(7.5), Axes(2*i,1+i),Eofill:=1, FillStyle:=full,FillOpacity:=0.9, FillColor:= blue, Width:=8, Path([-4,i,circle, -3+2*i,move,-3,-2,line, 0,2,2,-1,arc, 3,3+3*i,0.5,linearc, 1,-1+5*i,-3+2*i,bezier, closepath, ])
Point( <A1>, ..., <An> ).
Description : représente le nuage de points <A1> ... <An>.
view(2.75,4,0,1), Marges(0.75,0.5,0.5,0.5),size(7.5), Axes(Xmin+i*Ymin,0.25+0.2*i,1+i), pas:=0.001, Color:=red, DotScale:=0.1, Point( for r from Xmin to Xmax step pas do u:=0.5, for k from 1 to 25 do u:=r*u*(1-u) od, for k from 1 to 25 do u:=r*u*(1-u), r+i*u od od)
Polaire( <r(t)> [, n, 0/1] ).
Description : trace la courbe polaire d’équation ρ = r(t), <expression>. Le paramètre optionnel <n> est un entier (égal à 5 par défaut) qui permet de faire varier le pas de la manière suivante: lorsque la distance entre deux points consécutifs est supérieur à un certain seuil alors on calcule un point intermédiaire (par dichotomie), ceci peut être répété n fois. Si au bout de n itérations la distance entre deux points consécutifs est toujours supérieure au seuil, et si la valeur optionnelle 1 est présente, alors une discontinuité (jump) est insérée dans la liste des points.
view(-3,2,-2,3),Marges(0.25,0.25,0.25,0.25), size(7.5),Width:=4, Axes(0,1+i),NbPoints:=250,tMin:=-25,tMax:=25, courbe:=Get(Polaire((t+1)/(t-1))), ptDoubles:= courbe InterL courbe, Width:=8, Color:= blue, Ligne(courbe,0), DotStyle:=dotcircle, DotScale:=2, Point(ptDoubles), Label(1+2*i,"$r(t)=\dfrac{t+1}{t-1}$")
Spline( <V0>, <A0>,..., <An>, <Vn> ).
Description : trace la spline cubique passant par les points <A0> jusqu’à <An>. <V0> et <Vn> désignent les vecteurs vitesses aux extrémités [contraintes], si l’un d’eux est nul alors l’extrémité correspondante est considérée comme libre (sans contrainte).
view(-5,5,-5,5),Marges(0.25,0.25,0.25,0.25), size(7.5),Width:=4,Axes(0,1+i), A:= -4-3*i, B:=-2+2*i, C:=1-3*i, D:=4+3*i, LabelDot(A,"A","S",1),LabelDot(B,"B","N",1), LabelDot(C,"C","S",1),LabelDot(D,"D","O",1), Width:=8,Color:=red, Spline(0,A,B,C,D,0), Ligne([-4.5+4.5*i,-4+4.5*i],0), LabelStyle:=left, Label(-3.5+4.5*i,"libre"), Color:=blue,Spline(5,A,B,C,D,5*i), Ligne([-4.5+3.5*i,-4+3.5*i],0), Label(-3.5+3.5*i,"contrainte"), Width:=4, Arrows:=1, Ligne([A,A+2,jump,D,D+2*i],0)
La version propose quelques commandes de base pour faire du dessin bitmap. Ce dessin bitmap peut être enregistré (au format bmp) mais il n’est pas pris en compte par les autres exports du logiciel. Ces commandes ne sont fonctionnelles qu’avec la version GUI de TeXgraph. Chaque pixel est repéré son affixe x + iy où x et y sont deux entiers, l’origine est en haut à gauche de la zone de dessin marges exclues, l’axe Ox est dirigé vers la droite et l’axe Oy vers le bas.
DelBitmap().
Description : détruit le bitmap en cours.
MaxPixels().
Description : renvoie la taille de la zone graphique en pixels sous la forme: maxX+i*maxY, ainsi pour les coordonnées des pixels (coordonnées entières), l’intervalle des abscisses est [0 .. maxX] et celui des ordonnées [0 .. maxY]. Chaque pixel est repéré par des coordonnées entières, donc chaque pixel a une affixe a + ib avec a dans [0 .. maxX] et b dans [0 .. maxY]. L’origine étant le coin supérieur gauche de la zone graphique marges exclues.
NewBitmap( [fond] ).
Description : permet de créer un nouveau bitmap (vide). Par défaut la couleur du fond est le blanc.
Pixel( <liste> ).
Description : permet de d’allumer une <liste> de pixels. Cette liste est de la forme: [affixe, couleur, affixe, couleur, ...]. Les affixes des pixels sont de la forme a + ib avec a et b des entiers positifs ou nuls, l’origine étant le coin supérieur gauche de la zone graphique marges exclues.
Pixel2Scr( <affixe> ).
Description : permet de convertir l’<affixe> d’un pixel (coordonnées entières) en affixe dans le repère de l’utilisateur à l’écran.
Scr2Pixel( <affixe> ).
Description : permet de convertir l’<affixe> d’un point dans le repère de l’utilisateur à l’écran en coordonnées entières (affixe du pixel correspondant au point).
Exemple(s) : un ensemble de Julia, la commande est à placer dans un élément graphique utilisateur. L’image png a été obtenue à partir du bouton snapshot de l’interface graphique en prenant l’export bmp puis une conversion en png:
view(-1.5,1.5,-1,1),Marges(0,0,0,0),size(7.5), NewBitmap(), T:=100, m:=MaxPixels(), c:=-0.181-0.667*i, for x from 0 to Re(m) do Pixel( for y from 0 to Im(m) do N:=0, z:=Pixel2Scr(x+i*y), repeat z:=z^2+c, Inc(N,1) until (N=T) Or (abs(z)>2) od, x+i*y, MixColor(darkred,1-N/T,yellow,N/T) od ) od
angleD( <B>, <A>, <C>, <r> ).
Description : dessine l’angle $\widehat{BAC}$ avec un parallèlogramme de coté r.
Arc( <B>, <A>, <C>, <R> [, sens] ).
Description : trace un arc de cercle de centre <A> et de rayon <R>. L’arc est tracé partant de la droite (AB) jusqu’à la droite (AC), l’argument facultatif <sens> indique: le sens trigonométrique si sa valeur est 1 (valeur par défaut), le sens contraire si valeur est - 1.
view(-2.25,3.75,-2,5),Marges(0,0,0,0),size(7.5), A:=0, B:=3+i, C:=2+4*i, DotScale:=2, Width:=8, Ligne([B,A,C],0), Color:=red, LabelDot(A,"A","S",1), LabelDot(B,"B","N",1), LabelDot(C,"C","SE",1), Arrows:=1, Color:=blue, Arc(B,A,C,1,-1), Arc(B,A,C,2,1)
arcBezier( <B>, <A>, <C>, <r> [,sens] ).
Description : a le même effet que la macro graphique Arc mais l’arc est dessiné avec des courbes de Bezier.
axes( <[origine, etendueX, etendueY]>, <gradX+i*gradY> [, subdivX+i*subdivY, posOriginX+i*posOriginY, num, "texte", den, firstnum] ).
Description : pour tracer et graduer les axes passant par <origine> (affixe), elle s’utilise comme la commande Axes et utilise donc les variables xylabelpos et xyticks. Par défaut les axes occupent toute la fenêtre si les paramètres optionnels <etendueX> et <etendueY> sont omis. Le paramètre <etendueX> représente sous forme complexe l’intervalle des abcisses: xmin+i*xmax, de même pour les ordonnées avec le paramètre <etendueY>, les axes sont alors limités à ces intervalles. Remarque: pour préciser une valeur de <etendueY> sans préciser de valeur pour <etendueX>, il suffit de mettre jump à la place de <etendueX> (et non pas Nil!).
Le paramètre optionnel <subdivX+i*subdivY> indique le nombre de subdivisions par unité sur chaque axe (0 par défaut).
Le paramètre optionnel <posOriginX+i*posOriginY> permet de positionner le label de l’origine:
<posOriginX>=0: pas de label à l’origine (idem pour <posOriginY>=0),
<posOriginX>=1: label normal à l’origine (idem pour <posOriginY>=1),,
<posOriginX>=2: label décalé à droite de l’origine et en haut pour <posOriginY>=2 (valeurs par défaut),
<posOriginX>=-2 label décalé à gauche de l’origine et en bas pour <posOriginY>=-2.
Sur les 2 axes, chaque label est multiplié par la fraction <num/den> (1 par défaut), ajouté à <firstnum/den> (l’origine par défaut) et accompagné du <"texte"> au numérateur. Pour que le séparateur décimal soit la virgule à la place du point, il suffit de mettre la variable usecomma à la valeur 1. Cette macro est également sensible aux variables dollar (pour ajouter ou non des $ autour des labels des graduations), et nbdeci qui fixe le nombre de décimales affichées.
Exemple(s) : pour avoir des axes gradués en π / 2 en π / 2: axes(0, pi*(1+i)/2, 1+i, 2+2*i, 1, "\pi", 2, 0). Contrairement à la commande Axes, cette macro est sensible aux modifications de la matrice courante.
axeX( <[origine, posOrigine, etendue]>, <Xpas> [, Subdiv, labelPos , num, ""texte"", den, firstnum] ).
Description : pour tracer et graduer un axe des abscisses passant par <origine> et avec un pas de <Xpas>. Le paramètre <etendue> représente sous forme complexe l’intervalle des abscisses xmin+i*xmax, si celui-ci est omis, alors le tracé occupe la fenêtre. Remarque: pour préciser une valeur de <etendue> sans préciser de valeur pour <posOrigine>, il suffit de mettre jump à la place de <posOrigine> (et non pas Nil!).
<Subdiv> est le nombre de subdivisions par unité, chaque abscisse est multipliée par la fraction <num/den> (1 par défaut), ajoutée à <firstnum/den> (l’origine par défaut) et accompagnée du <"texte"> au numérateur. Pour que le séparateur décimal soit la virgule à la place du point, il suffit de mettre la variable usecomma à la valeur 1. Cette macro est également sensible aux variables dollar (pour ajouter ou non des $ autour des labels des graduations), et nbdeci qui fixe le nombre de décimales affichées.
Les paramètres optionnels <posOrigine> et <labelpos> permettent de positionner les labels:
<posOrigine>=0: pas de label à l’origine,
<posOrigine>=1: label normal à l’origine,
<posOrigine>=2: label décalé à droite à l’origine (valeur par défaut),
<posOrigine>=-2 label décalé à gauche à l’origine,
<labelPos>=0 : pas de label du tout,
<Re(labelpos)>=top: labels au-dessus,
Re(<labelPos>)=bottom : labels en-dessous (valeur par défaut),
Im(<Im(labelPos>)=1: labels orthogonaux à l’axe.
axeY(<[origine, posOrigine, etendue]>, <Ypas> [, Subdiv, labelPos , num, ""texte"", den, firstnum] ).
Description : pour tracer et graduer un axe des abscisses passant par <origine> et avec un pas de <Ypas>. Le paramètre <etendue> représente sous forme complexe l’intervalle des ordonnées ymin+i*ymax, si celui-ci est omis, alors le tracé occupe la fenêtre. Remarque: pour préciser une valeur de <etendue> sans préciser de valeur pour <posOrigine>, il suffit de mettre jump à la place de <posOrigine> (et non pas Nil!).
<Subdiv> est le nombre de subdivisions par unité, chaque ordonnée est multipliée par la fraction <num/den> (1 par défaut), ajoutée à <firstnum/den> (l’origine par défaut) et accompagnée du <"texte"> au numérateur. Pour que le séparateur décimal soit la virgule à la place du point, il suffit de mettre la variable usecomma à la valeur 1. Cette macro est également sensible aux variables dollar (pour ajouter ou non des $ autour des labels des graduations), et nbdeci qui fixe le nombre de décimales affichées.
Les paramètres optionnels <posOrigine> et <labelpos> permettent de positionner les labels:
<posOrigine>=0: pas de label à l’origine,
<posOrigine>=1: label normal à l’origine,
<posOrigine>=2: label décalé vers le haut à l’origine (valeur par défaut),
<posOrigine>=-2 label décalé vers le bas à l’origine,
<labelPos>=0 : pas de label du tout,
<Re(labelpos)>=left: labels à gauche de l’axe (valeur par défaut),
Re(<labelPos>=right : labels à droite de l’axe,
Im(<labelPos>)=1: labels orthogonaux à l’axe.
view(-5,5,-5,5),size(7.5), LabelSize:=footnotesize, //graphique du haut SaveWin(), view(-5,5,0.25,5),Width:=6, Arrows:=1, SetMatrix([2.5*i,2/pi,2*i]), axeX(0,pi/2,Nil,Nil,1,"",2), axeY(0,1), Arrows:=0, Color:=red, Width:=8, tMin:=-2*pi, tMax:=2*pi, Cartesienne(sin(x)), Label(pi*1.65+i,"f(x) = sin(x)"),RestoreWin(), //graphique du bas SaveWin(), Color:=black, view(-5,5,-5,-0.25), SetMatrix([-5.5*i,2,i]), Width:=6, Arrows:=1, usecomma:=1, axeX([i,0],0.5), axeY([i,0],1,Nil,Nil,1,"a"), Arrows:=0, Color:=blue, Width:=8, Cartesienne(x^2+1), Label(1+4.75*i,"g(x) = x2 + a"), RestoreWin()
background( <fillstyle>, <fillcolor> ).
Description : permet de remplir le fond de la fenêtre graphique avec le style et la couleur demandée. Cette macro met à jour la variable backcolor.
bbox().
Description : permet d’ajuster la fenêtre à la "bounding box" autour du dessin courant. Cette macro est destinée à être utilisée dans la ligne de commande en bas de la fenêtre principale, et non pas dans un élément graphique.
centerView( <affixe> ).
Description : permet de centrer la fenêtre graphique sur le point représenté par <affixe>, sans changer les dimensions courantes du graphique. Cette macro est plutôt destinée à être utilisée dans la ligne de commande en bas de la fenêtre principale.
Cercle( <A>, <r> [, B] ).
Description : trace un cercle de centre <A> et de rayon <r> lorsque le troisième paramètre est omis, sinon c’est le cercle défini par les trois points <A>, <r> et <B>.
Pour les macros Arc et Cercle, on peut s’attendre à des surprises dans le résultat final si le repère n’est pas orthonormé! Le repère est orthonormé lorsque les variables Xscale et Yscale sont égales, voir option Paramètres/Fenêtre.
view(-5,5,-1,3),Marges(0,0,0,0), size(7.5), Seg(-5,5), for t in [-4,-1.85,0,1.85,3] do M:=t-sin(t)+i*(1-cos(t)), I:=t+i, DotStyle:=cross, Point(I), DotStyle:=bigdot, Point(M), Cercle(I,1), Seg(M,I), Arrows:=1, Arc(M,I,t,0.5,t), Arrows:=0, LineStyle:=dashed, Seg(I,t), LineStyle:=solid od, Width:=8,Color:=red, Courbe( t-sin(t)+i*(1-cos(t)))
Clip( <liste> ).
Description : permet de clipper les éléments graphiques déjà dessinés avec la <liste> qui doit être une courbe fermée et simple. La macro peint l’extérieur de la courbe représentée par la <liste>.
Dbissec( <B>, <A>, <C>, <1 ou 2> ).
Description : dessine la bissectrice de l’angle $\widehat{BAC}$, intérieure si le dernier paramètre vaut 1 et extérieure pour la valeur 2.
Dcarre( <A>, <B>, <+/-1> [, rayon] ).
Description : dessine de carré de sommets consécutifs <A> et <B> dans le sens direct si le troisième paramètre vaut 1 (indirect pour - 1). Si le paramètre <rayon> est présent, alors les øg coins de la figure seront arrondis par un arc de cercle ayant le rayon mentionné.
Ddroite( <A>, <B> ).
Description : dessine la demi-droite [A, B).
Dmed( <A>, <B> [, angle droit(0/1)] ).
Description : dessine la médiatrice du segment [A, B]. Si le troisième paramètre vaut 1 (0 par défaut) alors un angle droit est dessiné.
domaine1( <f(x)> [, a, b] ).
Description : dessine la partie du plan comprise entre la courbe Cf, l’axe Ox et les droites x = a, x = b si a et b sont précisés, sinon x = tMin et x = tMax.
domaine2( <f(x)>, <g(x)> [, a, b] ).
Description : dessine la partie du plan comprise entre les courbes Cf, Cg et les droites x = a, x = b si a et b sont précisés, sinon x = tMin et x = tMax.
domaine3( <f(x)>, <g(x)> ).
Description : délimite la partie du plan comprise entre les courbes Cf et Cg avec x dans l’intervalle [tMin,tMax], en recherchant les points d’intersection.
view(-5,5,-4,5),size(7.5),tMin:=-5, Axes(-5,1+i,2+2*i), tMax:=-1, Cartesienne(sin(x)), tMax:=5, Cartesienne(2*cos(x)),tMin:=-3,tMax:=3, Cartesienne(x^2), A:=-4.5+(Ymin+1.75)*i, FillStyle:=full, FillOpacity:=0.5,FillColor:=green, LabelStyle:=left, LabelSize:=footnotesize, Dcarre(A+0.25*(-1+i), A+0.25*(1+i), -1), Label(A+0.4,"domaine2 sur [ - 4 ; - 1. 5] "), Inc(A,-0.75*i), FillColor:=blue, Dcarre(A+0.25*(-1+i), A+0.25*(1+i),-1), Label(A+0.4,"domaine3 entre 2cos(x) et x2 "), Inc(A,-0.75*i), FillColor:=red, Dcarre(A+0.25*(-1+i), A+0.25*(1+i),-1), Label(A+0.4,"domaine1 sur [1. 1 ; 4]"), FillColor:=red, domaine1(2*cos(x), 1.1, 4), FillColor:=green, domaine2(2*cos(x), sin(x),-4,-1.5), FillColor:=blue, domaine3(2*cos(x),x^2), Arrows:=2, tangente(2*cos(x),0.5,1.5)
Dparallel( <[A, B]> , <C> ).
Description : dessine la parallèle à la droite <[A,B]> passant par <C>.
Dparallelo( <A>, <B> , <C> [, rayon] ).
Description : dessine le parallèlogramme de sommets consécutifs <A>, <B> et <C>. Si le paramètre <rayon> est présent, alors les øg coins de la figure seront arrondis par un arc de cercle ayant le rayon mentionné.
Dperp( <[A, B]> , <C> [, angle droit(0/1)] ).
Description : dessine la perpendiculaire à la droite <[A,B]> passant par <C>. Si le troisième paramètre vaut 1 (0 par défaut) alors un angle droit est dessiné.
Dpolyreg( <centre> , <sommet>, <nombre de côtés> [, rayon] ).
Description : dessine le polygône régulier défini par le <centre>, un <sommet> et le <nb de côtés>. Si le paramètre <rayon> est présent, alors les øg coins de la figure seront arrondis par un arc de cercle ayant le rayon mentionné.
Dpolyreg( <sommet1>, <sommet2>, <nombre de cotés +sens*i> [, rayon] ).
Description : dessine le polygône régulier défini par deux sommets consécutifs <sommet1> et <sommet2>, le <nb de côtés>, et le <sens> (1 pour direct et - 1 pour indirect). Si le paramètre <rayon> est présent, alors les øg coins de la figure seront arrondis par un arc de cercle ayant le rayon mentionné.
DpqGoneReg( <centre> , <sommet>, <[p,q]> ).
Description : dessine le <p/q>-gône régulier défini par le <centre> et un <sommet>.
view(-5,5,-6,6),Marges(0,0,0,0),size(7.5), FillStyle:=full, FillColor:=lightpink, Color:=blue, Width:=8, DpqGoneReg(-2.5+2.5*i,-2.5+0.25*i, [7,3]), Label(-2.5+5*i,"[7,3]"), DpqGoneReg(2.5+2.5*i,2.5+0.25*i, [7,2]), Label(2.5+5*i,"[7,2]"), DpqGoneReg(-2.5-2.5*i,-2.5-0.25*i, [7,1]), Label(-2.5-5*i,"[7,1]"), DpqGoneReg(2.5-2.5*i,2.5-0.25*i, [6,2]), Label(2.5-5*i,"[6,2]")
drawSet( <ensemble> ).
Description : dessine un ensemble produit par les macros capB, cupB ou setminusB.
Drectangle( <A>, <B> , <C> [, rayon] ).
Description : dessine le rectangle de sommets consécutifs <A>, <B>, le côté opposé passant par <C>. Si le paramètre <rayon> est présent, alors les øg coins de la figure seront arrondis par un arc de cercle ayant le rayon mentionné.
ellipticArc( <B>, <A>, <C>, <RX>, <RY>, <sens(+/-1)> [, inclinaison] ).
Description : dessine un arc d’ellipse de centre <A>, allant de <B> à <C> de rayons <RX> et <RY>, l’axe portant le rayon <RX> ayant une certaine <inclinaison> par rapport à l’horizontale, celle-ci est en degrés et vaut 0 par défaut, le paramètre <sens> indique le sens de rotation, 1 pour le sens trigonométrique.
flecher( <liste>, <pos1, ..., posN> ).
Description : dessine des flèches le long de la ligne polygonale <liste>, la position de chaque flèche (pos1, ...) est un nombre entre 0 et 1 (0 pour début de la ligne et 1 pour fin de ligne), les flèches sont dessinées dans le sens de parcourt de la ligne, pour inverser une flèche on ajoute +i à la position.
Exemple(s) : flecher(Get(Cercle(0,3)), [0,0.5] )
GradDroite( <[A, origine + i*posOrigine, etendue]>, <[u, unit]>, <hautDiv>, <subdiv> [, poslab, orientation, num, ""texte"", den, firstnum] )
Description : gradue la droite passant par <A> et dirigée par le vecteur <u> (celui-ci n’est pas forcément unitaire), <hautdiv> est la hauteur des graduations en cm, <subdiv> est le nombre de subdivisions par unité.
Paramètres optionnels:
<origin>: indique la graduation de l’origine <A> (0 par défaut),
<posOrigin>: indique la position du label à l’origine <A>, plusieurs cas:
<posOrigin>=0: pas de label à l’origine,
<posOrigin>=1: label normal à l’origine (comme les autres)
<posOrigin>=2: label à l’origine décalé dans le sens du vecteur <u> (valeur par défaut),
<posOrigin>=-2: label à l’origine décalé dans le sens opposé du vecteur <u>.
<etendue>: représente l’intervalle des graduations sous forme complexe: min+i*max, le tracé de l’axe sera limité à cet intervalle. Si ce paramètre est omis, le tracé occupera la fenêtre.
<unit>: indique le pas des graduations sur l’axe (1 par défaut), cette valeur doit être positive.
<poslab> indique la position des labels par rapport à l’axe, ce paramètre prend les valeurs top ou bottom,
<orientation>: orientation des labels, la valeur i signifie que les labels sont orthogonaux à l’axe, sinon l’orientation représente le LabelStyle (left, right, top, ...),
chaque graduation est multipliée par la fraction <num/den> (1 par défaut), ajoutée à <firstnum/den> (l’origine par défaut) et accompagnée du <"texte"> au numérateur. Pour avoir une virgule comme spérateur décimal au lieu du point, il faut mettre la variable usecomma à la valeur 1. Cette macro est également sensible aux variables dollar (pour ajouter ou non des $ autour des labels des graduations), et nbdeci qui fixe le nombre de décimales affichées. Le nombre maximal de graduations est fixé par la variable maxGrad qui vaut 100 par défaut.
Exemple(s) : GradDroite([0,1+2*i],[1,0.5], xyticks, 1, bottom, i): signifie que la graduation de l’origine sera 1 avec un label décalé à droite, les graduations iront de 0.5 en 0.5, les labels seront sous l’axe et orthogonaux à l’axe.
LabelArc( <B>, <A>, <C>, <R>, <sens>, <"texte">, [, options] ).
Description : cette macro dessine un arc de cercle de centre <A>, de rayon <R> partant de la droite (AB) jusqu’à la droite (AC), l’argument facultatif <sens> indique: le sens trigonométrique si sa valeur est 1 (valeur par défaut), le sens contraire si valeur est -1. La macro ajoute également le <"texte">. Le paramètre <options> est une liste (facultative) de la forme [ option1:= valeur1, ..., optionN:=valeurN ], les options sont:
labelpos := < inside/outside >: positionnement du label (outside par defaut)),
labelsep := < distance en cm >: distance du label à l’arc (0.25cm par défaut).
rotation := < nombre >: angle en degrés que fait le label par rapport à l’horizontale (0 par défaut).
Il est possible dans la liste des options, de modifier des attributs comme Color par exemple.
LabelAxe( <x ou y>, <affixe>, <label> [, [labelPos,décalage en cm], mark(0/1)] ).
Description : permet d’ajouter un label sur un des axes <x ou y>, <affixe> désigne l’affixe du point où se fait l’ajout, <label> contient le texte à ajouter. Paramètres optionnels, <[labelPos, décalage en cm]> et <mark>:
Re(<labelpos>)=1 signifie en dessous pour Ox et à droite pour Oy (par défaut pour Ox),
Re(<labelpos>)=2 signifie au dessus pour Ox et à gauche pour Oy (par défaut pour Oy),
Im(<labelpos>)=-1 signifie un décalage sur la gauche pour Ox, vers le bas pour Oy, si le décalage n’est pas précisé, il vaut 0.25 cm par défaut,
Im(<labelpos>)=1 signifie un décalage sur la droite pour Ox, vers le haut pour Oy, si le décalage n’est pas précisé, il vaut 0.25 cm par défaut,
Im(<labelpos>)=0 signifie pas de décalage (valeur par défaut),
<mark>: indique si le point doit être marqué (dans le dotsyle courant).
LabelDot( <affixe>, <"texte">, <orientation> [, DrawDot, distance] ).
Description : cette macro affiche un texte à coté du point <affixe>. L’orientation peut être "N" pour nord, "NE" pour nord-est ...etc, ou bien une liste de la forme [longueur, direction] où direction est un complexe, dans ce deuxième cas, le paramètre optionnel <distance> est ignoré. Le point est également affiché lorsque <DrawDot> vaut 1 (0 par défaut) et on peut redéfinir la <distance> en cm entre le point et le texte (0.25cm par défaut).
LabelSeg( <A>, <B>, <"texte">, [, options] ).
Description : cette macro dessine le segment défini par <A> et <B>, et ajoute le <"texte">. Le paramètre <options> est une liste (facultative) de la forme [ option1:= valeur1, ..., optionN:=valeurN ], les options sont:
labelpos := < center/top/bottom >: positionnement du label (center par défaut),
labelsep := < distance en cm >: distance du label au segment lorsque labelpos vaut top ou bottom (0.25cm par défaut).
rotation := < nombre >: angle en degrés que fait le label par rapport à l’horizontale (par défaut le label est parallèle au segment).
Il est possible dans la liste des options, de modifier des attributs comme Color par exemple.
markangle( <B>, <A>, <C>, <r>, <n>, <espacement>, <longueur> ).
Description : même chose que markseg mais pour marquer un arc de cercle.
markseg( <A>, <B>, <n>, <espacement>, <longueur> [, angle] ).
Description : marque le segment [A, B] avec <n> petits segments, l’<espacement> est en unité graphique, et la <longueur> en cm. Le paramètre optionnel <angle> permet de définir en degré l’angle que feront les marques par rapport à la droite (AB) (45 degrés par défaut).
periodic( <f(x)>, <a>, <b> [, divisions, discontinuités] ).
Description : trace la courbe de la fonction périodique définie par y = f(x) sur la période [a; b], puis translate le motif pour couvrir l’intervalle [tMin; tMax]. Les deux paramètres optionnels sont identiques à ceux des courbes paramétrées (nombre de divisions et discontinuités).
view(-5,5,-5,5), size(7.5), Axes(0,1+i), Width:=8, Color:=red, periodic(if t>0 then 4 else 2 fi,-1,1,5,1), Color:=blue, periodic(2*abs(t)-1,-1,1), Color:=magenta, periodic(sin(t)-3,-pi/2,pi/2)
Rarc( <B>, <A>, <C>, <R>, <sens> ).
Description : comme la macro Arc sauf que l’arc de cercle est rond même si le repère n’est pas orthonormé, le rayon <R> est en centimètres.
Rcercle( <A>, <R> ) ou Rcercle( <A>, <B>, <C> ).
Description : dessine un cercle rond même si le repère n’est pas orthonormé. Dans la première forme, le rayon <R> est en centimètres.
Rellipse( <O>, <RX>, <RY> [, inclinaison] ).
Description : comme la commande Ellipse sauf que celle-ci est insensible au repère écran, les rayons sont en centimètres.
RellipticArc( <B>, <A>, <C>, <RX>, <RY>, <sens(+/-1)> [, inclinaison] ).
Description : comme la macro ellipticArc sauf que celle-ci est insensible au repère écran, les rayons sont en centimètres.
RestoreWin().
Description : restaure la fenêtre graphique ainsi que la matrice 2D enregistrées lors du dernier appel à la macro SaveWin.
SaveWin().
Description : enregistre la fenêtre graphique ainsi que la matrice 2D courantes, sur une pile. Cette macro va de paire avec la macro RestoreWin.
Exemple(s) : plusieurs graphiques sur un seul: voir cet exemple.
Seg( <A>, <B> ).
Description : dessine le segment [A, B].
set( <nom>, <affixe centre> [, options] ).
Description : dessine un ensemble en forme de patatoïde, <affixe centre> désigne le centre de cet ensemble, et le paramètre <nom> est une chaîne contenant le nom de cet ensemble. Le paramètre <options> est une liste (facultative) de la forme [ option1:= valeur1, ..., optionN:=valeurN ], les options sont:
scale := < entier positif >: représente l’échelle (1 par défaut),
rotation := < angle en degrés >: permettant d’incliner le dessin (0 degré par défaut),
labels := < 0/1 >: pour afficher ou non le nom de l’ensemble.
labelsep := < distance en cm >: distance du label au bord de l’ensemble (0.45cm par défaut)
Il est possible dans la liste des options, de modifier des attributs comme LabelStyle par exemple.
La macro renvoie en résultat la liste des points de la courbe dessinant l’ensemble.
setB( <nom>, <affixe centre> [, options] ).
Description : dessine un ensemble en forme de patatoïde à l’aide de courbes de Bézier, <affixe centre> désigne le centre de cet ensemble, et le paramètre <nom> est une chaîne contenant le nom de cet ensemble. Le paramètre <options> est une liste (facultative) de la forme [ option1:= valeur1, ..., optionN:=valeurN ], les options sont:
scale := < entier positif >: représente l’échelle (1 par défaut),
rotation := < angle en degrés >: permettant d’incliner le dessin (0 degré par défaut),
labels := < 0/1 >: pour afficher ou non le nom de l’ensemble.
labelsep := < distance en cm >: distance du label au bord de l’ensemble (0.45cm par défaut)
Il est possible dans la liste des options, de modifier des attributs comme LabelStyle par exemple.
La macro renvoie en résultat la liste des points de contrôle de la courbe représentant l’ensemble. Cette liste peut-être utilisée ensuite pour déterminer une intersection (voir capB), une réunion (voir capB) ou une différence (voir setminusB).
size( <largeur + i*hauteur> [, ratio(Xscale/Yscale)] )
Description : permet de fixer les tailles du graphique: <largeur> et <hauteur> (marges incluses) en cm. Si le paramètre <hauteur> est nul, alors on considère que hauteur=largeur.
Si le paramètre <ratio> est omis, les échelles sur les deux axes sont calculées pour que la figure entre au plus juste dans le cadre fixé, tout en conservant le ratio courant.
Si <ratio> est égal à 0 alors les échelles sont calculées de manière à obtenir exactement la taille souhaitée (le ratio courant n’est donc vraisemblablement pas conservé).
Le repère est orthonormé lorsque le paramètre <ratio> vaut 1.
NB: un appel aux fonctions Fenetre Marges ou à la macro view, modifiera la taille du graphique. Il est donc préférable de déterminer les marges et la fenêtre graphique avant de fixer la taille.
La largeur d’un graphique est donnée par la formule:
et la hauteur est donnée par:
suite( <f(x)>, <u0>, <n> ).
Description : représentation graphique de la suite définie par un + 1 = f(un), de premier terme <u0> et jusqu’au rang <n>. Cette macro ne représente que les "escaliers".
view(-0.1,1.1,-0.1,1.1),size(7.5), Arrows:=1,Axes(0,1/2+i/4),Arrows:=0, u0:=0.3,nb:=20, Width:=6, Color:=darkseagreen, Droite(1,-1,0), Color:=red, tMin:=0, tMax:=1, Width:=8, Cartesienne(4*x*(1-x)), Width:=6, Color:=blue, Label(0.5+1.05*i,"un + 1 = 4un(1 - un)"), LabelDot(u0, "u0","S",1), suite(4*x*(1-x), u0,nb)
tangente( <f(x)>, <x0> [, longueur] ).
Description : trace la tangente à la courbe cartésienne y = f(x) au point d’abscisse <x0>, on trace un segment de la <longueur> indiquée (en cm) ou la droite entière si la longueur est omise.
tangenteP( <f(t)>, <t0> [,longueur] ).
Description : trace la tangente à la courbe paramétrée par <f(t)> au point de paramètre <t0>, on trace un segment de la <longueur> indiquée (en cm) ou la droite entière si la longueur est omise.
view( <xmin>, <xmax>, <ymin>, <ymax> ) ou view( <[xmin+i*ymin, xmax+i*ymax]> )
Description : change la fenêtre graphique courante et conserve l’échelle. Attention: ceci change la taille du graphique, celle-ci peut-être modifiée avec la macro size.
Exemple(s) : dans un élément graphique utilisateur, la commande [ view(-4, 4,-3, 3), size(12) ] va fixer la fenêtre graphique à [ - 4, 4] × [ - 3, 3], et la taille du graphique à 12cm en conservant le ratio courant. Il est important de respecter l’ordre (view avant size).
wedge( <B>, <A>, <C>, <r> )
Description : dessine le secteur angulaire défini par l’angle $\widehat{BAC}$ avec un rayon <r>.
zoom( <+/-1> )
Description : permet de faire un zoom arrière/avant.
Option Elément graphique/Créer/Utilisateur du menu. ↩