Source : saisons1A.mp

verbatimtex
%&latex
\documentclass{article}
\usepackage{fourier}
\begin{document}
etex
 

beginfig(1);
% excentricité, demi-grand axe, demi-petit axe
numeric e,a,b;
e = 0.4;
a = 100;
b = a * sqrt(1 - e * e) ;
path cp,el;
% cercle principal
cp = fullcircle scaled 2a;
% ellipse 
el = fullcircle xscaled 2a yscaled 2b;
 
pair S,S',T,O;
% soleil réel
S = point 1.2 of el;
% soleil déplacé
S'= point 1.2 of cp;
% terre
T = (sqrt(a**2-b**2),0);
% origine du cercle principal
O = (0,0);
 
% axes
draw (-1.1a,0) -- (1.1a,0);
draw (0,-1.1a) -- (0,1.1a);
 
draw cp;
draw el;
draw S'--(xpart S',0) dashed evenly scaled 1;
draw O--S';
draw T--S;
 
path t[];
t1 = (fullcircle scaled 20) cutafter (O--S');
t2 = ((fullcircle scaled 20) shifted T) cutafter (T--S);
drawarrow t1;
drawarrow t2;
 
dotlabel.urt(btex $S$ etex, S);
dotlabel.urt(btex $S'$ etex, S');
dotlabel.lrt(btex $T$ etex, T);
dotlabel.ulft(btex $A$ etex, (-a,0));
dotlabel.llft(btex $B$ etex, (0,b));
dotlabel.urt(btex $P$ etex, (a,0));
label.llft(btex $x$ etex, (1.1a,0));
label.llft(btex $y$ etex, (0,1.1a));
label.lft(btex $b$ etex, (0,a/2));
label.top(btex $a$ etex, (-a/2,0));
label.lft(btex $r$ etex,.5[T,S]);
label.urt(btex $u$ etex,point .5 of t1);
label.urt(btex $v$ etex,point .5 of t2);
dotlabel.llft(btex $O$ etex, O);
endfig;
end