Gnuplot In Action
Site : http://www.manning.com/janert/
Les données utilisées sont celles qui sont décrites dans le livre de Philipp K. Janert et que vous trouverez dans une archive sur le site du livre.
Toutes les figures du livre ne sont pas représentées ici…
Chapitre 1
Figure 1.1
set t png
set o "marathon.png"
plot "marathon" using 1:2 with boxes
Figure 1.2
#!/usr/bin/gnuplot
set t png
set o "dlacluster.png"
unset border
unset xtics
unset ytics
unset key
set size square
plot "dlacluster" using 2:3 with dots
Chapitre 5
#!/usr/bin/gnuplot
set t png
set o "test.png"
test
Chapitre 9
Planche couleur 1
#!/usr/bin/gnuplot
set t postscript eps color
set o "palette-1.eps"
set palette model RGB defined \
( 0 "red", 0.5 "yellow", 1 "green" )
test palette
#!/usr/bin/gnuplot
set t postscript eps color
set o "palette-2.eps"
set palette model RGB defined ( 0 "red", 0.1 "yellow", 1 "green" )
test palette
Planche couleur 3
#!/usr/bin/gnuplot
set t postscript eps color
set o "listing9-1.eps"
unset key
set view 90,0 # View from the side
set isosamples 200,2 # Good resolution along x-axis,
# few points along y-axis
unset ytics # Not needed
set xtics offset 0,-2 # Push tic marks down from default position
set border 4095 # Turn on all borders
set xyplane 0 # Center the plot within the bounding box
set palette defined ( 0 'red', 0.25 'red', 0.5 'green', \
1.5 'green', 1.75 'red', 2 'red')
splot sin(x)**3 + 0.3*sin(5*x) w l palette
Planche couleur 5
#!/usr/bin/gnuplot
set t postscript eps color
set o "fractal-1.eps"
set pm3d
set view map
set size square
unset surface
set ytics 0.225,0.02,0.265
set xtics -0.745,0.02,-0.705
unset key
set logscale cb
set palette model RGB defined \
(log(15) 'white', log(20) '#ff6666', log(35) '#cc99cc', \
log(50) '#3366ff', log(100) '#99ffcc', log(133) '#339900', \
log(167) '#66ff33', log(200) '#996633', log(250) '#ff9900',\
log(300) '#ffff33', log(999) 'white', log(9900) 'white', \
log(9901) 'black', log(10000) 'black' )
splot "fractal"
#!/usr/bin/gnuplot
set t postscript eps color
set o "fractal-2.eps"
set pm3d
set view map
set size square
unset surface
set ytics 0.225,0.02,0.265
set xtics -0.745,0.02,-0.705
unset key
set logscale cb
blue = 2.0/3.0
green = 1.0/3.0
set palette model HSV defined \
( log(15) blue 0.7 0.6, log(50) blue 0.6 0.9, \
log(100) green 0.5 1, log(200) green 0.7 0.5, \
log(1000) green 0.9 0.4, log(5000) 0 0 1, \
log(9900) 0 0 1, log(9901) 0 1 0, log(10000) 0 1 0 ) \
splot "fractal"
Figure 9.3
#!/usr/bin/gnuplot
set terminal postscript eps
set o "fractal.eps"
set pm3d
set view map
set size square
unset surface
set isosamples 300
set ytics 0.225,0.02,0.265
set xtics -0.745,0.02,-0.705
unset key
set palette defined \
( 0 'white', 10 'white', 225 'black', 1500 'white', \
9999 'white', 10000 'black')
splot "fractal"
