Animations

La cissoïde droite

Soit Δ la droite d'équation x=2a, C un cercle de centre (-a,0) et de rayon a, et H un point courant de la droite Δ. On définit le pôint P comme l'intersection de la droite (OH) avec le cercle C privé du point O. On détermine ensuite M comme le milieu du segment [HP]. Quand H décrit Δ, M décrit la cissoïde droite.

verbatimtex
%&latex
\documentclass{article}
\usepackage[garamond]{mathdesign}
\usepackage{amsmath}
\usepackage[utf8]{inputenc}
\usepackage[frenchb]{babel}
\begin{document}
etex
 
u:=1cm;
 
a:=3u;
path cercle, droite, cissoide;
pair M,O;
 
M:=(-a,0);
O:=(0,0);
droite:=(2a,-8u)--(2a,8u);
cercle:= fullcircle scaled 2a shifted M;
 
for i:=0 upto 400:
beginfig(i);
  path drtour,demid;
  pair M,P,Hb,H;
  drawarrow (-8u,0)--(8u,0);
  drawarrow (0,-8u)--(0,8u);
  H:=(2a,i/10*u-20u);
  Hb:=(-xpart H, -ypart H);
  demid:= 0.01[O,Hb]--2[O,Hb];
  P:=demid intersectionpoint cercle;
  M:=.5[H,P];
  if i=0:
    cissoide:=M;
  else:
    cissoide:=cissoide--M;
  fi;
  draw cercle withpen pencircle scaled 0.8pt withcolor blue;
  draw droite withpen pencircle scaled 0.8pt withcolor blue;
  draw H--P dashed evenly withpen pencircle scaled 0.8pt withcolor green;
  draw cissoide withpen pencircle scaled 1pt withcolor red;
  dotlabel.urt(btex $M$ etex,M);
  dotlabel.rt(btex $H$ etex,H);
  dotlabel.llft(btex $P$ etex,P);
  dotlabel.lrt(btex $O$ etex, O);
  label.bot(btex $x$ etex, (7.6u,0));
  label.rt(btex $y$ etex, (0,7.6u));
  label.bot(btex $2a$ etex, (-a,0));
  label.bot(btex $2a$ etex, (a,0));
  label.urt(btex $\mathcal{C}$ etex, (-0.5a,a));
  label.rt(btex $\Delta$ etex, (2a,-7.5u));
  label.bot(btex \textit{Cissoïde droite} :  
    \(\left\{\begin{array}{l} x=\dfrac{2at^2}{1+t^2}\\[2mm] 
	y=\dfrac{2at^3}{1+t^2} \end{array}\right.\) etex,(-4u,6.3u));
  clip currentpicture to (-8u,-8u)--(-8u,8u)--(8u,8u)--(8u,-8u)--cycle;
endfig;
endfor;
end.