Animations

La courbe du Kappa

Soit une droite horizontale à une hauteur a de l'origine O. On prend un point courant P appartenant à cette droite, on trace le cercle de centre O et de rayon la distance de P à l'axe des ordonnées, on trace alors le segment [OP] qui coupe le cercle au point M. On réalise la même construction symétriquement par rapport à l'axe des abscisses (on a les points Q et N). Quand P et Q décrivent les droites auquelles ils appartiennent, alors M et N décrivent la courbe Kappa (l'appellation fait allusion au κ minuscule).

%@AUTEUR: Maxime Chupin
verbatimtex
%&latex
\documentclass{article}
\usepackage[garamond]{mathdesign}
\usepackage{amsmath}
\begin{document}
etex
 
u:=1cm;
path kappah, kappab;
 
for i:=0 upto 320:
 beginfig(i);
  pair O,P,M,Q,N,Oh,Ob;
  path hori, horih, horib,cercle,POdr,QOdr;
  h:=3.5u;
  O=(0,0);
  Oh:=(0,h);
  Ob:=(0,-h);
  drawarrow (-7u,0)--(7u,0);
  drawarrow (0,-5u)--(0,5u);
  hori:=(-7u,0)--(7u,0);
  horih:=hori shifted (0,h);
  horib:=hori shifted (0,-h);
  P:=(-8u+16/320*i*u,h);
  Q:=(-8u+16/320*i*u,-h);
  c:=xpart P;
  cercle:= fullcircle scaled 2c;
  POdr:= O--P;
  QOdr:= O--Q;
  M:=POdr intersectionpoint cercle;
  N:=QOdr intersectionpoint cercle;
  if i=0:
    kappah:=M;
    kappab:=N;
  else:
    kappah:=kappah--M;
    kappab:=kappab--N;
  fi;
  draw cercle withpen pencircle scaled 0.8pt withcolor blue;
  draw horih dashed evenly withpen pencircle scaled 0.7pt withcolor green;
  draw horib dashed evenly withpen pencircle scaled 0.7pt withcolor green;
  draw O--P dashed evenly withpen pencircle scaled 0.7pt withcolor green;
  draw O--Q dashed evenly withpen pencircle scaled 0.7pt withcolor green;
  draw P--Q dashed evenly withpen pencircle scaled 0.7pt withcolor green;
  draw kappah withpen pencircle scaled 1pt withcolor red;
  draw kappab withpen pencircle scaled 1pt withcolor red;
 
  dotlabel.urt(btex $P$ etex, P);
  dotlabel.llft(btex $M$ etex, M);
  dotlabel.ulft(btex $N$ etex, N);
  dotlabel.lrt(btex $Q$ etex, Q);
  label.top(btex $x$ etex, (6.5u,0));
  label.lft(btex $y$ etex, (0,4.5u));
  dotlabel.llft(btex $(0,a)$ etex, (0,3.5u));
  label.top(btex \textit{Kappa} : 
    \(\left\{\begin{array}{l} 
	x=a\left(\frac{1}{\sin t}-\sin t\right)\\y=a\cos t 
    \end{array}\right.\) etex, (3u,3.6u));
  clip currentpicture to (-7u,-5u)--(-7u,5u)--(7u,5u)--(7u,-5u)--cycle;
 endfig;
endfor;
end.