Animations

Orbite

Un satellite S est en rotation circulaire autour de la terre avec une vitesse v₀. À un instant t, on change instantanément l'orientation du vecteur vitesse tout en gardant la même norme que v₀. La trajectoire est alors elliptique (v₀ est telle que l'énergie mécanique est négative). L'animation montre l'évolution de la trajectoire en fonction de l'angle formé entre le vecteur v₀ et le nouveau vecteur vitesse.

%@AUTEUR: Maxima Chupin
%@DATE: 21 mars 2007
 
verbatimtex
%&latex
\documentclass{article}
\usepackage{amsmath}
\usepackage[mdugm]{mathdesign}
\usepackage[latin1]{inputenc}
\usepackage{color}
\begin{document}
etex
u=2.5cm;
 
for i:= 0 upto 28: 
 beginfig(i+1);
  path droite, droiter, ellipse;
  pair T,S,R,O,F,V;
  numeric a,b,o;
  T:= (0,0);
  fill fullcircle scaled 0.2u withcolor blue;
  a:=1.4u;
  S:=(-a,0);
  draw T--S dashed evenly withcolor green;
  R:=(a*cosd(90+2.5*i),a*sind(90+2.5*i));
  droite := 5[T,R]--5[R,T];
  droiter := droite rotated 90 shifted S;
  draw droite shifted S dashed evenly;
  draw droite shifted T dashed evenly;
  draw droiter dashed evenly;
  O = droite intersectionpoint droiter; 
  b := abs(S-O);
  ellipse = fullcircle xscaled 2a yscaled 2b;
  o:=abs(T-O);
  F:=(2*o*cosd(90+2.5*i),2*o*sind(90+2.5*i));
  draw S--F dashed evenly withcolor green;
  V:= (u*cosd(90+2.5*i),u*sind(90+2.5*i));
 
  pickup pencircle scaled 1pt;
  drawarrow S--(xpart S,u)  withcolor 0.8white;
  draw fullcircle scaled 2a dashed evenly withcolor 0.8white;
  draw ellipse  rotated (90+2.5*i) shifted O withcolor red;
  drawarrow S--(V shifted S);
 
 
  label.ulft(btex $\overrightarrow{v}$ etex, (V shifted S));
  label(btex \textcolor{white}{$T$} etex, T);
  dotlabel.llft(btex $S$ etex,S);
  label.bot(btex $a$ etex,(-(a/2),0));
  if i<>0:
    dotlabel.urt(btex $O$ etex, O);
    dotlabel.ulft(btex $T'$ etex, F);
    label.top(btex $a$ etex,((xpart S + xpart F)/2,(ypart S + ypart F)/2));
    label.urt(btex $b$ etex,((xpart S + xpart O)/2,(ypart S + ypart O)/2));
  fi;
  clip currentpicture to (-3u,-2u)--(2u,-2u)--(2u,3u)--(-3u,3u)--cycle;
 endfig;
endfor;
 
 
for i:= 28 downto 0: 
 beginfig(30 +(28-i));
  path droite, droiter, ellipse;
  pair T,S,R,O,F,V;
  numeric a,b,o;
  T:= (0,0);
  fill fullcircle scaled 0.2u withcolor blue;
  a:=1.4u;
  S:=(-a,0);
  draw T--S dashed evenly withcolor green;
  R:=(a*cosd(90+2.5*i),a*sind(90+2.5*i));
  droite := 5[T,R]--5[R,T];
  droiter := droite rotated 90 shifted S;
  draw droite shifted S dashed evenly;
  draw droite shifted T dashed evenly;
  draw droiter dashed evenly;
  O = droite intersectionpoint droiter;
  b := abs(S-O);
  ellipse = fullcircle xscaled 2a yscaled 2b;
  o:=abs(T-O);
  F:=(2*o*cosd(90+2.5*i),2*o*sind(90+2.5*i));
  draw S--F dashed evenly withcolor green;
  V:= (u*cosd(90+2.5*i),u*sind(90+2.5*i));
 
  pickup pencircle scaled 1pt;
  drawarrow S--(xpart S,u)  withcolor 0.8white;
  draw fullcircle scaled 2a dashed evenly withcolor 0.8white;
  draw ellipse  rotated (90+2.5*i) shifted O withcolor red;
  drawarrow S--(V shifted S);
 
  label.ulft(btex $\overrightarrow{v}$ etex, (V shifted S));
  label(btex \textcolor{white}{$T$} etex, T);
  dotlabel.llft(btex $S$ etex,S);
  label.bot(btex $a$ etex,(-(a/2),0));
  if i<>0:
    dotlabel.urt(btex $O$ etex, O);
    dotlabel.ulft(btex $T'$ etex, F);
    label.top(btex $a$ etex,((xpart S + xpart F)/2,(ypart S + ypart F)/2));
    label.urt(btex $b$ etex,((xpart S + xpart O)/2,(ypart S + ypart O)/2));
  fi;
 
  clip currentpicture to (-3u,-2u)--(2u,-2u)--(2u,3u)--(-3u,3u)--cycle;
 endfig;
endfor;
end.