Animations

Podaire d'un cercle par rapport à un point

%@AUTEUR: MAxime Chupin
%@DATE: 24/12/2007
 
verbatimtex
%&latex
\documentclass[12pt]{article}
\usepackage[garamond]{mathdesign}
\begin{document}
etex
 
u:=2cm;
 
vardef proj(expr P,M,N) =
    % On protège le symbole H si toutefois il est déjà utilisé et on 
    % déclare que c'est un point.
    save H; pair H;
    % On indique que H est un barycentre de M et N, sans préciser
    % exactement le coefficient...
    H = whatever [M,N];
    % On indique que le vecteur PH est égal à un certain nombre de fois
    % le vecteur NM tourné de 90 degrés.
    H - P = whatever * (M - N) rotated 90;
    % Les équations ci-dessus étant suffisante pour définir H, on demande 
    % à la macro de le rendre.
    H
  enddef;
  path pod,cercle,tang,proje,drop;
 
 
for i:=0 upto 180:
 beginfig(i+1);
  pair O,A,P,M,N;
  % les axes
  drawarrow (-5u,0)--(3u,0) withpen pencircle scaled 0.7pt;
  drawarrow (0,-4u)--(0,4u) withpen pencircle scaled 0.7pt;
  O:=(0,0);
  A:=(-4u,0);
  cercle:=fullcircle scaled (4u);
  draw cercle withpen pencircle scaled 0.7pt withcolor blue;
  % notre point courant sur le cercle  
  P:=2u*(cosd(2i),sind(2i));
  drop:=6[O,P]--6[P,O];
  % le rayon
  draw O--P dashed evenly 
    withpen pencircle scaled 0.7pt withcolor green;
  % tangente au cercle passant au point P
  tang:= drop rotated 90 shifted P;
  draw tang dashed evenly 
    withpen pencircle scaled 0.8pt withcolor green;
  % droite de projection de A sur la tangente au cercle
  proje:= drop shifted A;
  draw proje dashed evenly 
    withpen pencircle scaled 0.8pt withcolor green;
  % M l'intersection
  M:=proje intersectionpoint tang;
  % la courbe enfin!
  if i=0 :
   pod:=M;
  else :
   pod:=pod--M;
  fi;
  draw pod withpen pencircle scaled 1pt withcolor red;
  dotlabel.ulft(btex $A(-d,0)$ etex, A);
  dotlabel.urt(btex $P$ etex,P);
  dotlabel.urt(btex $O$ etex, O);
  dotlabel.lrt(btex $M$ etex,M);
  label.top(btex $r$ etex,(u,0));
  label.bot(btex \textit{Une podaire du cercle} $\mathcal{C}$ : 
    $\left\{\begin{array}{l} x=(r+d\cos t)\cos t-d\\ 
    y=(r+d\cos t )\sin t \end{array}\right.$ etex, (0.2u,4u));
  label.ulft(btex $\mathcal{C}$ etex,2u*(cosd(120),sind(120)));
  clip currentpicture to (-5u,-4u)--(3u,-4u)--(3u,4u)--(-5u,4u)--cycle;
 endfig;
endfor;
end