Source : Droitesparalleles.mp

% Choix de LaTeX
verbatimtex
%&latex
\documentclass[a4paper]{article}
\usepackage[latin1]{inputenc}
\usepackage[frenchb]{babel}
\begin{document}
etex
%%[geometrie]
input geometriesyr16;
input outilssyr;
vues:=8;
pair p[],A,B,I,J;
A=u*(1,4);%p0
B=u*(10,3);%p1
I=u*(7,6);%p4
J=I shifted(B-A);
p5=projection(I,A,B);
figure(0,0,15u,10u);
trace feuillet withcolor blanc;
marque_p:="croix";
nomme.llft(A);
nomme.top(B);
marque_p:="plein";
nomme.ulft(I);
marque_p:="non";
trace droite(A,B);
picture fond;
fond=currentpicture;
fin;
figure(0,0,15u,10u);
draw fond;
draw equerre(A,B,I,1,1);
fin;
figure(0,0,15u,10u);
draw fond;
draw equerre(A,B,I,1,1);
draw regle(2[p5,I],2[I,p5],1);
fin;
for vue=1 upto vues:
  figure(0,0,15u,10u);
  draw regle(2[p5,I],2[I,p5],1);
  draw equerre(A shifted((vue/vues)*(I-p5)),B shifted((vue/vues)*(I-p5)),I,1,1);
  trace fond;
  drawarrow p5--(vue/vues)[p5,I] withcolor jaune withpen pencircle scaled 2bp;
  fin;
endfor;
figure(0,0,15u,10u);
draw equerre(A,B,I,1,1) shifted(I-p5);
draw regle(2[J,I],2[I,J],1);
trace fond;
fin;
pair K,L;
K=demidroite(J,I) intersectionpoint feuillet;
L=demidroite(I,J) intersectionpoint feuillet;
path cadre;
cadre=(u*(1,8))--(u*(5,8))--(u*(5,10))--(u*(1,10))--cycle;
picture cadrage;
cadrage=image(
  fill cadre withcolor ciel;
  draw cadre;
  label(btex \begin{minipage}{3.5cm}\large
    La parallèle à la droite $(AB)$ passant par le point $I$.
    \end{minipage}
    etex,iso(u*(1,8),u*(5,10))
    ) withcolor rouge;
  drawarrow (u*(3,8))--(0.08[K,L]) withpen pencircle scaled 1.5bp;
  );
for vue=1 upto vues:
  figure(0,0,15u,10u);
  draw regle(2[J,I],2[I,J],1);
  trace fond;
  draw crayon(K,L,(vue/vues),1.5);
  trace K--(vue/vues)[K,L] withpen pencircle scaled 1.5bp withcolor jaune;
  trace cadrage;
  fin;
endfor;
end