Source : ellipseanim1.mp

input geometriesyr16;
u:=0.8cm;
pair F,F',M,K,G,T[];
F'=u*(3,4);
F=u*(7,4);
path cc,cd,ce;
cc=cercles(F',5u);
vues=20;
for vue=0 upto vues:
  figure(-2.5u,-1.5u,8.5u,9.5u);
  trace feuillet withcolor blanc;
  trace cc;
  trace droite(F,F');
  label.ulft(btex $\cal C$ etex,pointarc(cc,150));
  marque_p:="plein";
  nomme.lrt(F');
  nomme.lrt(F);
  marque_p:="non";
  G:=pointarc(cc,vue*360/vues);
  K:=iso(G,F);
  M:=(F'--G) intersectionpoint mediatrice(F,G);
  cd:=cercles(M,abs(M-G));
  trace arccercle(pointarc(cd,315),pointarc(cd,180),M);
  trace F'--G--F--M dashed evenly;
  trace 3/2[M,K]--3/2[K,M] dashed evenly;
  for j=0 step 2 until 360:
    T[j]=pointarc(cc,j);
  endfor;
  ce:=
  for j=0 step 2 until 360:
    (droite(F',T[j]) intersectionpoint mediatrice(F,T[j]))..
  endfor
  cycle;
  trace subpath(0,vue*length ce/vues) of ce withcolor orange;
  if vue<>10:
    trace codeperp(M,K,G,5);
  fi;
  nomme.ulft(M);
  nomme.top(G);
  nomme.urt(K);
  fin;
endfor;
end