Source : trigo.mp

beginfig(1);
numeric u ;
u=4.5cm;
drawarrow (-1.2*u,0)--(1.2*u,0);
drawarrow (0,-1.2*u)--(0,1.2*u);
draw fullcircle scaled 9cm ;
drawoptions(dashed evenly);
path t[] ;
t[1]=(u,0)--(cosd(60)*u,sind(60)*u)--(0,0);
draw t[1];
for k=2 upto 6 : t[k]=t[1] rotatedaround ((0,0),60*(k-1));
  draw t[k];
endfor;
path c[] ;
c1 =(cosd(60)*u,-sind(60)*u)--(cosd(60)*u,sind(60)*u) ;
draw c1 dashed evenly;
c2 = c1 shifted (-u,0) ;
draw c2 dashed evenly;
z[1]=(u,0);
for l=2 upto 6:
  z[l]=z[1] rotatedaround ((0,0),60(l-1));
endfor;
drawoptions();
dotlabel.lrt(btex $0$ etex,(u,0));
label.lrt(btex $1 \over2$ etex,(u/2,0));
label.lrt(btex $- {1 \over 2}$ etex,(-u/2,0));
dotlabel.llft(btex $\pi$ etex,(-u,0));
 
dotlabel.urt(btex ${\pi \over 3}$ etex, z[2]);
dotlabel.ulft(btex ${2\pi \over 3}$ etex,z[3]);
dotlabel.llft(btex $-{2\pi \over 3}$ etex,z[5]);
dotlabel.lrt(btex $-{\pi \over 3}$ etex,z[6]);
label.llft(btex ${\sqrt{3} \over 2}$ etex,(0,sqrt(3)*u/2));
label.ulft(btex $-{\sqrt{3} \over 2}$ etex,(0,-sqrt(3)*u/2));
 
drawoptions(dashed evenly);
path p[] ;
p[1]=(0,u)--(cosd(30)*u,sind(30)*u)--(0,0);
draw p[1];
for k=2 upto 6 : p[k]=p[1] rotatedaround ((0,0),60*(k-1));
  draw p[k];
endfor;
path s[] ;
s1 =(-cosd(30)*u,sind(30)*u)--(cosd(30)*u,sind(30)*u) ;
draw s1 dashed evenly;
s2 = s1 shifted (0,-u) ;
draw s2 dashed evenly;
 
pair y[];
y[1]=(cosd(30)*u,sind(30)*u);
for l=2 upto 6:
  y[l]=y[1] rotatedaround ((0,0),60(l-1));
endfor;
drawoptions();
dotlabel.urt(btex ${\pi \over 6}$ etex,y[1]);
dotlabel.urt(btex ${\pi \over 2}$ etex, y[2]);
dotlabel.ulft(btex ${5\pi \over 6}$ etex,y[3]);
dotlabel.llft(btex $-{5\pi \over 6}$ etex,y[4]);
dotlabel.llft(btex $-{\pi \over 2}$ etex,y[5]);
dotlabel.lrt(btex $-{\pi \over 6}$ etex,y[6]);
label.llft(btex ${\sqrt{3} \over 2}$ etex,(sqrt(3)*u/2,0));
label.lrt(btex $-{\sqrt{3} \over 2}$ etex,(-sqrt(3)*u/2,0));
label.llft(btex ${1 \over 2}$ etex,(0,u/2));
label.llft(btex $-{1 \over 2}$ etex,(0,-u/2));
 
drawoptions(dashed evenly);
 
path r[] ;
r[1]=(cosd(45)*u,-sind(45)*u)--(cosd(45)*u,sind(45)*u)--(0,0);
draw r[1];
for k=2 upto 4 : r[k]=r[1] rotatedaround ((0,0),90*(k-1));
  draw r[k];
endfor;
 
pair w[];
w[1]=(u,0);
for n=2 upto 8:
  w[n]=w[1] rotatedaround ((0,0),45(n-1));
endfor;
drawoptions();
dotlabel.urt(btex ${\pi \over 4}$ etex, w[2]);
dotlabel.urt(btex ${\pi \over 2}$ etex,w[3]);
dotlabel.ulft(btex ${3\pi \over 4}$ etex,w[4]);
dotlabel.llft(btex ${\pi}$ etex,w[5]);
dotlabel.llft(btex $-{3\pi \over 4}$ etex,w[6]);
dotlabel.llft(btex $-{\pi \over 2}$ etex,w[7]);
dotlabel.lrt(btex $-{\pi \over 4}$ etex,w[8]);
label.ulft(btex ${\sqrt{2} \over 2}$ etex,(sqrt(2)*u/2,0));
label.urt(btex $-{\sqrt{2} \over 2}$ etex,(-sqrt(2)*u/2,0));
label.lrt(btex ${\sqrt{2} \over 2}$ etex,(0,sqrt(2)*u/2));
label.urt(btex $-{\sqrt{2} \over 2}$ etex,(0,-sqrt(2)*u/2));
 
endfig;
end