Retour

Source : perpendiculaire.mp

Animation flash


perpendiculaire.mp
prologues:=2;
verbatimtex
%&latex
\documentclass[a4paper,12pt]{article}
\usepackage[latin1]{inputenc}
\usepackage[frenchb]{babel}
\begin{document}
etex
%%[geometrie]
input geometriesyr16;
input outilssyr;
%[Animation]
vues:=10;
pair p[],q[];
pair A,B,I;
A=u*(1,2);%p0
B=u*(8,3);%p1
I=u*(7,6);%p4
p5=projection(I,A,B);
p6=1/3[A,B];
figure(0,0,11u,8u);
trace feuillet withcolor blanc;
marque_p:="croix";
nomme.bot(A);
nomme.bot(B);
marque_p:="plein";
nomme.lft(I);
marque_p:="non";
draw droite(A,B) withcolor blue;
picture fond;
currentpicture=fond;
fin;
_nfig:=0;
figure(0,0,11u,8u);
trace fond;
trace equerre(A,B,p6,1,1);
fin;
for vue=1 upto vues :
  figure(0,0,11u,8u);
  trace fond;
  pair g[],G;
  G=(vue/vues)[p6,p5]-p6;
  g[vue]=p6 shifted G;
  trace equerre(A,B,g[vue],1,1);
  drawarrow p6--g[vue] withpen pencircle scaled 2bp withcolor green;
  fin;
endfor;
for vue=0 step 2 until vues:
  figure(0,0,11u,8u);
  trace fond;
  trace equerre(A,B,p5,1,1);
  drawarrow p6--p5 withpen pencircle scaled 2bp withcolor green;
  trace crayon(p5,I,(vue/vues),1.5);
  trace p5--(vue/vues)[p5,I] withcolor orange withpen pencircle scaled 2bp;
  fin;
endfor;
figure(0,0,11u,8u);
trace fond;
drawarrow p6--p5 withpen pencircle scaled 2bp withcolor green;
trace p5--I withcolor orange withpen pencircle scaled 2bp;
fin;
pair K,L;
K=demidroite(I,p5) intersectionpoint feuillet;
L=demidroite(p5,I) intersectionpoint feuillet;
for vue=0 step 2 until vues:
  figure(0,0,11u,8u);
  trace fond;
  trace regle(K,L,1);
  drawarrow p6--p5 withpen pencircle scaled 2bp withcolor green;
  trace crayon(K,p5,(vue/vues),1.5);
  trace p5--I withcolor orange withpen pencircle scaled 2bp;
  trace K--(vue/vues)[K,p5] withcolor orange withpen pencircle scaled 2bp;
  fin;
endfor;
for vue=0 step 2 until vues:
  figure(0,0,11u,8u);
  trace fond;
  trace regle(K,L,1);
  drawarrow p6--p5 withpen pencircle scaled 2bp withcolor green;
  trace crayon(I,L,(vue/vues),1.5);
  trace p5--I withcolor orange withpen pencircle scaled 2bp;
  trace K--p5 withcolor orange withpen pencircle scaled 2bp;
  trace I--(vue/vues)[I,L] withcolor orange withpen pencircle scaled 2bp;
  fin;
endfor;
figure(0,0,11u,8u);
trace fond;
drawarrow p6--p5 withpen pencircle scaled 2bp withcolor green;
trace droite(K,L) withcolor orange withpen pencircle scaled 2bp;
fin;
figure(0,0,11u,8u);
trace fond;
drawarrow p6--p5 withpen pencircle scaled 2bp withcolor green;
trace droite(K,L) withcolor orange withpen pencircle scaled 2bp;
trace crayon(p5,p5+10*unitvector(I-p5),1,1.5);
fin;
figure(0,0,11u,8u);
trace fond;
drawarrow p6--p5 withpen pencircle scaled 2bp withcolor green;
trace droite(K,L) withcolor orange withpen pencircle scaled 2bp;
trace (p5+10*unitvector(I-p5))--(p5+10*unitvector(I-p5)+10*unitvector(B-p5));
trace crayon(p5+10*unitvector(I-p5)+10*unitvector(B-p5),p5+10*unitvector(I-p5),0,1.5);
fin;
figure(0,0,11u,8u);
trace fond;
drawarrow p6--p5 withpen pencircle scaled 2bp withcolor green;
trace droite(K,L) withcolor orange withpen pencircle scaled 2bp;
trace codeperp(I,p5,B,10);
trace crayon(p5+10*unitvector(B-p5),p5+10*unitvector(I-p5)+10*unitvector(B-p5),0,1.5);
fin;
for k=0 upto 5:
  figure(0,0,11u,8u);
  trace fond;
  drawarrow p6--p5 withpen pencircle scaled 2bp withcolor green;
  trace droite(K,L) withcolor orange withpen pencircle scaled 2bp;
  trace codeperp(I,p5,B,10);
  fin;
endfor;
end